RSolve not solving discrete Rossler system

Question

I'm working with chaotic attractors, and testing some continuous-> discrete equivalences. I've made a continuous simulation of the Rossler system this way

a = 0.432; b = 2; c = 4;
Rossler = {
    x'[t] == -y[t] - z[t], 
    y'[t] == x[t] + a*y[t],
    z'[t] == b + x[t]*z[t]-c*z[t]};
sol = NDSolve[
  {Rossler, x[0] == y[0] == z[0] == 0.5}, 
  {x, y, z}, {t,500}, MaxStepSize -> 0.001, MaxSteps -> Infinity]

Now, when trying to evaluate a discrete equivalent system with RSolve, Mma doesn't do anything, not even an error, it just can't solve it.

RosslerDiscreto = {
       x[n + 1] == x[n] - const1*(y[n] + z[n]),
       y[n + 1] == 1 - a*const2)*y[n] + const2*x[n], 
       z[n + 1] == (z[n]*(1 - const3) + b*const3)/(1 - const3*x[n])}

I want to know if there is a numerical function for RSolve, analogous as the NDSolve is for DSolve. I know i can make the computation with some For[] cycles, just want to know if it exists such function.

Answer 1

RecurrenceTable is the numeric analogue to RSolve:

rosslerDiscreto = {
  x[n+1] == x[n] - C[1]*(y[n] + z[n]),
  y[n+1] == (1 - a*C[2])*y[n] + C[2]*x[n],
  z[n+1] == (z[n]*(1 - C[3]) + b*C[3]) / (1 - C[3]*x[n]),
  x[0] == y[0] == z[0] == 0.5
} /. {a->0.432, b->2, c->4, C[1]->0.1, C[2]->0.1, C[3]->0.1};
coords = RecurrenceTable[rosslerDiscreto, {x,y,z}, {n,0,1000}];
Graphics3D@Point[coords]