Search code examples
haskellpolymorphismtypeclassparametric-polymorphism

Haskell: Non type-variable argument in the constraint

I created some functions to get some comfort with 2D geometry. In this example I use Geom2D from CubicBezier package.

Complete code of my program: https://gist.github.com/nskeip/3784d651ac646a67c5f246f048949af4

{-# LANGUAGE MultiParamTypeClasses, FlexibleInstances, FlexibleContexts #-}
import Geom2D

left :: (Num a) => Point a -> a -> Point a
left (Point x y) n = Point (x - n) y

right :: (Num a) => Point a -> a -> Point a
right (Point x y) n = Point (x + n) y

up :: (Num a) => Point a -> a -> Point a
up (Point x y) n = Point x (y - n)

down :: (Num a) => Point a -> a -> Point a
down (Point x y) n = Point x (y + n)

They work like this:

> (Point 0 0) `up` 10
Point 0.0 -10.0

Where Point is defined like this:

data Point a = Point {
  pointX :: !a,
  pointY :: !a
  } deriving (Eq, Ord, Functor, Foldable, Traversable)

And everything was fine untill I thought: "Hey, it would be nice to make that functions (actualy, operators) work with thigs like Line - not only Point"

So I declared a class (not taking left and right to keep thigs simple):

class Num n => Moving p n where
  up'    :: n -> p -> p
  down'  :: n -> p -> p

  up'    n = down'  (-n)
  down'  n = up'    (-n)

And an instance of Moving for Point a data type:

instance Num a => Moving (Point a) a where
  up' n (Point x y) = Point x (y - n)

But when I try to use it, I got an error:

✗ ghci ./uno.hs 
GHCi, version 7.10.3: http://www.haskell.org/ghc/  :? for help
[1 of 1] Compiling Main             ( uno.hs, interpreted )
Ok, modules loaded: Main.
*Main> let p = Point { pointX = 0, pointY = 0 } 
*Main> up' 10 p

<interactive>:3:1:
    Non type-variable argument in the constraint: Moving (Point a) n
    (Use FlexibleContexts to permit this)
    When checking that ‘it’ has the inferred type
      it :: forall n a. (Num a, Moving (Point a) n) => Point a

And the thing that confuses me much: I put the FlexibleContexts pragma to the pragma listing in the head, but ghcu still suggest me to get it included.

How can I fix my class / instance to get parametric polymorphism working? :)

Solution

  • And the thing that confuses me much: I put the FlexibleContexts pragma to the pragma listing in the head, but ghcu still suggest me to get it included.

    This only enables the extension in the module itself. To write this code in GHCi, you need to enable the extension in GHCi: :set -XFlexibleContexts.

    But this is only part of the problem. It looks like for your class p should determine n: you can only move a Point a up and down by a, right? But as it stands, nothing stops you from defining more Moving (Point a) SomeOtherType instances, and the compiler doesn't assume you won't. So a and n in the inferred type are completely unrelated, where you want them to be the same. This can be fixed by adding the FunctionalDependencies extension and changing the class declaration to say

    class Num n => Moving p n | p -> n where

    which means exactly that there can't be instances with same p and different n.

    I think that's enough to make it work. The code will still be underdetermined because it allows any numeric a, but defaulting rules will pick Integer.