XText Validator shows Parse Error in wrong line

Question

I am currently developing a small dsl with the following (shortend) grammar:

grammar mydsl with org.eclipse.xtext.common.Terminals hidden(WS, SL_COMMENT)
generate mydsl "uri::mydsl"

CommandSet:
    (commands+=Command)*
;

Command:
    (commandName=CommandName LBRACKET (args=ArgumentList)? RBRACKET EOL ) |
;
terminal LBRACKET:
    '('
;
terminal RBRACKET:
    ')'
;
terminal EOL:
    ';'
;

As you can see, I use a semicolon as a EOL seperator and it works just fine for me. The problem occurs with the built-in syntax validator when working with the dsl in eclipse. When I miss a semicolon, the validator throws an syntax error in the wrong line:

Is there an error with my grammar? Thanks ;)

Answer 1

Here is a small DSL loosely based on your example. Basically, I do not consider linebreaks as "hidden" any longer (i.e. they will no longer be ignored by the parser), only the whitespaces. Note new terminals MY_WS and MY_NL as well as modified hidden statement in the grammar header (I also added some comments at relevant places). This approach just gives you some general idea and you can experiment with it to achieve what you want. Note, that if linebreaks are no longer hidden, you will need to take account of them in your grammar rules.

grammar org.xtext.example.mydsl.MyDsl
    with org.eclipse.xtext.common.Terminals
    hidden( MY_WS, SL_COMMENT )   // ---> hide whitespaces and comments only, not linebreaks!
generate mydsl "uri::mydsl"

CommandSet:
     (commands+=Command)*
;

CommandName:
    name=ID
;

ArgumentList:
   arguments += STRING (',' STRING)*
;

Command:
     (commandName=CommandName LBRACKET (args=ArgumentList)? RBRACKET EOL);

terminal LBRACKET:
   '('
;
terminal RBRACKET:
   ')'
;
terminal EOL:
   ';' MY_NL?    // ---> now an optional linebreak at the end!
;

terminal MY_WS: (' '|'\t')+;    // ---> whitespace characters (formerly part of WS)
terminal MY_NL: ('\r'|'\n')+;   // ---> linebreak characters (no longer hidden)

Here is an image demonstrating the resulting behavior.