Getting a duplicate class found exception in android build.gradle.kts file

Question

I'm trying to add a new dependency for passing safe arguments from one fragment to another but doing so will generate duplicate files. Leading to duplicate file exception, This is my build.gradle.kts Module file,

plugins {
    id("com.android.application")
    id("org.jetbrains.kotlin.android")
}

android {
    namespace = "com.example.androidtrivia"
    compileSdk = 34

    defaultConfig {
        applicationId = "com.example.androidtrivia"
        minSdk = 24
        targetSdk = 34
        versionCode = 1
        versionName = "1.0"

        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
    }

    buildTypes {
        release {
            isMinifyEnabled = false
            proguardFiles(
                getDefaultProguardFile("proguard-android-optimize.txt"),
                "proguard-rules.pro"
            )
        }
    }
    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_1_8
        targetCompatibility = JavaVersion.VERSION_1_8
    }
    kotlinOptions {
        jvmTarget = "1.8"
    }
    buildFeatures {
        dataBinding = true
        viewBinding = true
    }
}

dependencies {
    val navVersion = "2.7.6"

    implementation("androidx.core:core-ktx:1.12.0")
    implementation("androidx.appcompat:appcompat:1.6.1")
    implementation("com.google.android.material:material:1.11.0")
    implementation("androidx.constraintlayout:constraintlayout:2.1.4")
    testImplementation("junit:junit:4.13.2")
    androidTestImplementation("androidx.test.ext:junit:1.1.5")
    androidTestImplementation("androidx.test.espresso:espresso-core:3.5.1")
    // navigation
    implementation("androidx.navigation:navigation-fragment-ktx:$navVersion")
    implementation("androidx.navigation:navigation-ui-ktx:$navVersion")

    implementation("androidx.navigation:navigation-safe-args-gradle-plugin:$navVersion")

}

This is the error message

Caused by: com.android.builder.merge.DuplicateRelativeFileException: 2 files found with path 'META-INF/AL2.0' from inputs:

I tried adding Safe Arguments when passing arguments from one fragment to another but upon adding

    implementation("androidx.navigation:navigation-safe-args-gradle-plugin:$navVersion")

in dependency section i'm getting the error.

I want to use safe arguments.

Answer 1

This is because META-INF/AL2.0 is included in multiple gradle files. Please modify your app/build.gradle to include following

packaging {
    resources {
        excludes += "/META-INF/{AL2.0,LGPL2.1}"
    }
}

remove

  implementation("androidx.navigation:navigation-safe-args-gradle-plugin:$navVersion")

from app/build.gradle

and in project build.gradle update with

buildscript {
    dependencies {
        classpath("androidx.navigation:navigation-safe-args-gradle-plugin:2.7.6")
    }
}