Issues were found when checking AAR metadata: androidx.core:core:1.12.0-alpha01 and androidx.core:core-ktx:1.12.0-alpha01

Question

I am working on a project and today the build is not working anymore. The error is the following:

2 issues were found when checking AAR metadata:

1. Dependency 'androidx.core:core:1.12.0-alpha01' requires libraries and applications that depend on it to compile against codename "UpsideDownCake" of the Android APIs.

   :app is currently compiled against android-33.

   Recommended action: Use a different version of dependency 'androidx.core:core:1.12.0-alpha01', or set compileSdkPreview to "UpsideDownCake" in your build.gradle file if you intend to experiment with that preview SDK.

2. Dependency 'androidx.core:core-ktx:1.12.0-alpha01' requires libraries and applications that depend on it to compile against codename "UpsideDownCake" of the Android APIs.

   :app is currently compiled against android-33.

   Recommended action: Use a different version of dependency 'androidx.core:core-ktx:1.12.0-alpha01', or set compileSdkPreview to "UpsideDownCake" in your build.gradle file if you intend to experiment with that preview SDK.

From my research, I understand that the version from the error message were released yesterday, according to the official documentation.

Below are the build.gradle scripts that the project is using. In my build.gradle I have implementation 'androidx.core:core-ktx:1.9.0'. I don't understand why another version is added at the build phase and also why androidx.core:core:1.12.0-alpha01 is added.

build.gradle:

buildscript {

    apply from: './dependencies.gradle'

    repositories {
        google()
        mavenCentral()
        jcenter()
        gradlePluginPortal()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:7.4.0'
        classpath 'com.google.gms:google-services:4.3.14'
        classpath 'com.google.firebase:firebase-crashlytics-gradle:2.9.2'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$versions.kotlin_version"
        classpath "com.google.dagger:hilt-android-gradle-plugin:$versions.hilt_android"
    }
}

allprojects {
    repositories {
        google()
        mavenCentral()
        jcenter()
        maven { url "https://maven.google.com" }
        maven { url 'https://jitpack.io' }
        maven { url = "https://jcenter.bintray.com" }
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

dependencies.gradle:

ext.versions = [
    minSdkLib        : 23,
    compileSdk       : 33,
    versionCode      : 8,
    versionName      : '1.0.8',

    kotlin_version : '1.8.0',
    hilt_android : '2.44',
    hilt_compiler : '2.44',
]

build.gradle (app):

    plugins {
    id 'com.android.application'
    id 'kotlin-android'
    id 'kotlin-kapt'
    id 'kotlin-parcelize'

    id 'com.google.gms.google-services'
    id 'com.google.firebase.crashlytics'
    id 'dagger.hilt.android.plugin'
    id 'org.jetbrains.kotlin.android'
}

java {
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(11))
    }
}

apply from: '../dependencies.gradle'

android {
    compileSdkVersion versions.compileSdk
    buildToolsVersion "30.0.3"

    lintOptions {
        checkReleaseBuilds false
        // Or, if you prefer, you can continue to check for errors in release builds,
        // but continue the build even when errors are found:
        abortOnError false
    }

    buildFeatures {
        dataBinding = true
        // For view binding:
        viewBinding true
    }

    defaultConfig {
        applicationId "***"
        minSdkVersion versions.minSdkLib
        targetSdkVersion versions.compileSdk
        versionCode versions.versionCode
        versionName versions.versionName
        multiDexEnabled true
        vectorDrawables.useSupportLibrary = true
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        signingConfig signingConfigs.debug
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
            debuggable false
        }

        debug {
            debuggable true
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }

    compileOptions {
        // Flag to enable support for the new language APIs
        coreLibraryDesugaringEnabled true

        sourceCompatibility JavaVersion.VERSION_11
        targetCompatibility JavaVersion.VERSION_11
    }

    kotlinOptions {
        jvmTarget = '11'
    }

    packagingOptions {
        exclude 'META-INF/proguard/androidx-annotations.pro'
    }

    packagingOptions {
        exclude 'META-INF/DEPENDENCIES'
        exclude 'META-INF/LICENSE'
        exclude 'META-INF/LICENSE.txt'
        exclude 'META-INF/license.txt'
        exclude 'META-INF/NOTICE'
        exclude 'META-INF/NOTICE.txt'
        exclude 'META-INF/notice.txt'
        exclude 'META-INF/ASL2.0'
    }

}

dependencies {
    implementation fileTree(dir: "libs", include: ["*.jar"])

    implementation 'androidx.core:core-ktx:1.9.0'
    implementation 'androidx.appcompat:appcompat:1.6.0'
    implementation 'androidx.constraintlayout:constraintlayout:2.1.4'
    implementation 'androidx.navigation:navigation-fragment-ktx:2.5.3'
    implementation 'androidx.navigation:navigation-ui-ktx:2.5.3'

    implementation 'androidx.annotation:annotation:1.5.0'
    implementation "androidx.lifecycle:lifecycle-runtime-ktx:2.5.1"
    implementation "androidx.lifecycle:lifecycle-common-java8:2.5.1"
    implementation "androidx.lifecycle:lifecycle-livedata-ktx:2.5.1"
    /* Work */
    implementation 'androidx.work:work-runtime:2.7.1'

    implementation 'com.google.android.material:material:1.8.0'
    // Added Dependencies
    implementation "androidx.recyclerview:recyclerview:1.2.1"
    //
    implementation 'android.arch.lifecycle:extensions:1.1.1'
    implementation 'androidx.activity:activity-ktx:1.6.1'

    implementation("io.coil-kt:coil:1.2.0")

    /* Android 6.0 (Marshmallow) permission */
    implementation 'com.karumi:dexter:6.2.3'

    /* This is a logger with a small, extensible API which provides
       utility on top of Android's normal Log class. */
    implementation 'com.jakewharton.timber:timber:4.7.1'

    implementation 'com.squareup.retrofit2:retrofit:2.9.0'
    implementation "com.squareup.okhttp3:okhttp:4.10.0"
    implementation 'com.squareup.okhttp3:logging-interceptor:4.10.0'

    implementation "com.squareup.retrofit2:converter-moshi:2.9.0"
    implementation "com.squareup.moshi:moshi-kotlin:1.14.0"
    implementation 'com.squareup.moshi:moshi:1.14.0'
    implementation 'androidx.lifecycle:lifecycle-viewmodel-ktx:2.5.1'
    kapt 'com.squareup.moshi:moshi-kotlin-codegen:1.14.0'
    implementation 'com.squareup.retrofit2:converter-gson:2.9.0'
    // Dagger Hilt
    implementation "com.google.dagger:hilt-android:$versions.hilt_android"
    implementation 'org.chromium.net:cronet-embedded:108.5359.79'
    kapt "com.google.dagger:hilt-android-compiler:$versions.hilt_compiler"
    kapt 'androidx.hilt:hilt-compiler:1.0.0'

    // Paging
    implementation "androidx.paging:paging-runtime-ktx:3.1.1"

    /* Kotlin coroutines */
    implementation "org.jetbrains.kotlinx:kotlinx-coroutines-core:1.6.4"
    implementation "org.jetbrains.kotlinx:kotlinx-coroutines-android:1.6.4"

    implementation "org.jetbrains.kotlinx:kotlinx-serialization-json:1.4.1"
    implementation("org.jetbrains.kotlinx:kotlinx-datetime:0.3.2")
    coreLibraryDesugaring 'com.android.tools:desugar_jdk_libs:2.0.0'


    /* ssp for text size for all multiple devices */
    implementation 'com.intuit.ssp:ssp-android:1.0.6'
    /* sdp for all multiple devices size */
    implementation 'com.intuit.sdp:sdp-android:1.0.6'

    /* Image picker and Camera */
    implementation 'com.github.dhaval2404:imagepicker-support:1.7.1'

    /* Crash reporter in debug builds only */
    debugImplementation 'com.balsikandar.android:crashreporter:1.1.0'

    // Biometric
    implementation 'androidx.biometric:biometric:1.1.0'

    // FCM
    implementation platform('com.google.firebase:firebase-bom:31.0.2')
    implementation 'com.google.firebase:firebase-analytics-ktx'
    implementation 'com.google.firebase:firebase-crashlytics-ktx'
    implementation 'com.google.firebase:firebase-messaging-ktx'

    // Calendar
    implementation 'com.applandeo:material-calendar-view:1.8.0-rc01'

    // Horizontal Calendar
    implementation 'devs.mulham.horizontalcalendar:horizontalcalendar:1.3.4'

    // Stripe SDK
    implementation 'com.stripe:stripe-android:20.16.1'

    // Testing libraries
    testImplementation 'junit:junit:4.13.2'
    testImplementation "com.google.truth:truth:1.1.3"
    androidTestImplementation "com.google.truth:truth:1.1.3"
    androidTestImplementation 'androidx.test.ext:junit:1.1.5'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.5.1'
    androidTestImplementation "androidx.test:core-ktx:1.5.0"
    debugImplementation 'androidx.fragment:fragment-testing:1.5.5'

    //
    implementation 'de.hdodenhof:circleimageview:3.1.0'
    /// Zoom image
    implementation 'com.jsibbold:zoomage:1.3.1'
    /// S: Glide
    implementation 'com.github.bumptech.glide:glide:4.12.0'
    kapt 'com.github.bumptech.glide:compiler:4.12.0'

    // Bar
    implementation 'com.github.hadiidbouk:ChartProgressBar-Android:2.0.6'

    // One Signal
    implementation 'com.onesignal:OneSignal:[4.0.0, 4.99.99]'

    // Color picker
    implementation 'com.github.yukuku:ambilwarna:2.0.1'
    implementation 'com.squareup.retrofit2:adapter-rxjava2:2.6.1'
    implementation group: 'com.squareup.retrofit2', name: 'adapter-rxjava2', version: '2.6.1'

    // Toast
    implementation 'com.github.ahmmedrejowan.CuteToast:CuteToast:1.2'
}

Answer 1

I had the same problem, but my project didn't have this generic dependency:

androidx.core:core-ktx:+

But some of my dependencies had it (you can see it with the Gradle "Dependency analyser"). So you need to tell Gradle to force a specific dependency version for your dependencies:

configurations.all {
    resolutionStrategy {
        force("androidx.core:core-ktx:1.9.0")
    }
}