Calculate production capacity per product/day up to goal

Question

I have the following data.

Available resources data per day:

A	B	C	D	E	F	G	H	I	J	K	L	M	N
2	resources	day
3		1	2	3	4	5	6	7	8	9	10	11	12
4	empl.1	8	8	4	2	2	4	4			8	8
5	empl.2		8		4		4			8	4		8
6	empl.3

And different products and it's production per hour (per employee) and the required quantity per part:

P	Q	R	S
2	product	production/hour	required qty
3
4	prod.1	1	60
5	prod.2	1	6
6	prod.3	2	4

From this data I want to calculate the number of products that can be produced per day based on the available employees for the day and the production capacity for that product up until the goal is reached for that product.

---

edit: calculation from original post was calculating to hours spent per product per day only, not to qty of products produced; also the MOD-part gave wrong calculation results if the daily produced qty exceeds the goal

I use the following formula to calculate the above (used in C11 and dragged to the right):

=LET(
prod,BYROW($B11:B13,LAMBDA(r,SUM(r))),
reached,--(prod<$S$4:$S$6),
dayprod,IFERROR(SUM(C4:C6)/SUM(reached*$R$4:$R$6),0)*reached*$R$4:$R$6,
IF(prod+dayprod>$S$4:$S$6,dayprod-((prod+dayprod)-$S$4:$S$6),dayprod))

This results in the following:

A	B	C	D	E	F	G	H	I	J	K	L	M	N
9	product	day
10		1	2	3	4	5	6	7	8	9	10	11	12
11	prod.1	2	8	4	6	2	8	4	0	8	12	6	0
12	prod.2	2	4	0	0	0	0	0	0	0	0	0	0
13	prod.3	4	0	0	0	0	0	0	0	0	0	0	0

This formula sums the hours from the employees available that day and divides their hours over the products that did not reach the goal yet. If the goal is reached the available hours are divided over the remaining products to produce.

Screenshot of the data + current result:

Now the problem I'm having is the following:

If the goal is reached for a product somewhere halfway the day the dayprod-((prod+dayprod)-$S$4:$S$6)-part of the function calculates the remaining hours of production for that product for that day, but the available hours from the employees are divided over each product that needs production still, but let's take the following example:

prod.1, day 2: value 8

prod.2, day 2: value 4

The 8 for prod.1 is calculated based on both prod.1 & prod.2 in need for production still and both take 1 hour per person to produce one. Having 16 hours available that day that means a capacity of 8 for each.

But the challenge lies in the goal being reached halfway the day. In fact the first 4 hours are used by both employees to produce 4 of each product. The last 4 hours both employees can focus on prod.1 resulting in not qty 4 of production for the last 4 hours, but 4 + 4 which results in a total of 12 being produced for prod.1, not 8 like now calculated.

How can I get the formula to add the remaining time to the remaining products?

---

Original post, prior to edit, containing error (not calculating to number of products, but to number of hours spent per product per day only)

I use the following formula to calculate the above (used in C11 and dragged to the right):

=LET(
prod,BYROW($B11:B13,LAMBDA(r,SUM(r))),
reached,--(prod<$S$4:$S$6),
dayprod,IFERROR(SUM(C4:C6)/SUM(reached*$R$4:$R$6),0)*reached*$R$4:$R$6,
IF(prod+dayprod>$S$4:$S$6,dayprod-MOD(prod+dayprod,$S$4:$S$6),dayprod))

This results in the following:

A	B	C	D	E	F	G	H	I	J	K	L	M	N
9	product	day
10		1	2	3	4	5	6	7	8	9	10	11	12
11	prod.1	2	8	4	6	2	8	4	0	8	12	6	0
12	prod.2	2	4	0	0	0	0	0	0	0	0	0	0
13	prod.3	4	0	0	0	0	0	0	0	0	0	0	0

This formula sums the hours from the employees available that day and divides their hours over the products that did not reach the goal yet. If the goal is reached the available hours are divided over the remaining products to produce.

Screenshot of the data + current result:

Now the problem I'm having is the following:

If the goal is reached for a product somewhere halfway the day the MOD-part of the function calculates the remaining qty for that product for that day, but the available hours from the employees are divided over each product that needs production still, but let's take the following example:

prod.1, day 2: value 8

prod.2, day 2: value 4

The 8 for prod.1 is calculated based on both prod.1 & prod.2 in need for production still and both take 1 hour per person to produce one. Having 16 hours available that day that means a capacity of 8 for each.

But the challenge lies in the goal being reached halfway the day. In fact the first 4 hours are used by both employees to produce 4 of each product. The last 4 hours both employees can focus on prod.1 resulting in a total of 12 being produced for prod.1, not 8.

I kind of broke my head on getting this far, but from here I could use some help.
How can I get the MOD part of the formula to add the remaining time to the remaining products?

Answer 1

I was able to find a solution to my problem.

I had to use the result from the formula in place and check if the sum up to the current day (including that day's production) exceeds the goal. If so I needed to get the time difference between the day's production and that day's production needed to get to the goal. The difference is the time of production to be added to the remaining part(s) for that day that did not reach the goal yet, also not when adding the day's production.

This results in the following formula in C11 dragged to the right:

=LET(
     prod,BYROW($B11:B13,LAMBDA(r,SUM(r))),
     prodhour,$R$4:$R$6,
     goal,$S$4:$S$6,
     reached,--(prod<goal),
     dayprod,(IFERROR(SUM(C$4:C$6)/SUM(reached*prodhour),0)*reached*prodhour)*prodhour,
preres,IF(prod+dayprod>goal,dayprod-((prod+dayprod)-goal),dayprod),
     timecorr,(dayprod*(dayprod<>preres)-preres*(dayprod<>preres))/prodhour,
     reachedcorr,reached*(timecorr=0),
     dayprodcorr,(IFERROR(SUM(timecorr)/SUM(reachedcorr*prodhour),0)*reachedcorr*prodhour)*prodhour,
IF(prod+dayprod>=goal,dayprod-((prod+dayprod)-goal),dayprod+dayprodcorr))

Where preres is the previous result (from where I got stuck in the opening post). And the corr parts are taking care of the correction if goal is reached for a product and there was still production time remaining.