infinite value while using cumulative constraint

Question

I am stuck with a cumulative constraint I seem not to use properly, I seek for help ! :)

I have tasks with precedence and, for some of them, required & forbidden resources. I need to decide when to start a task & who to assign to it.

To do so, I'm using an array of decision variable resource_allocation:

array[Tasks, Resources] of var 0..1: resource_allocation; %Selection of resources per task.

To manage the required/forbidden resources, I used the following:

% Mandatory & Forbidden constraint allocation
constraint forall(t in Tasks, r in resource_required[t])(resource_allocation[t,r]=1);
constraint forall(t in Tasks, r in resource_forbidden[t])(resource_allocation[t,r]=0);

resource_required being set of int storing the resources number that are required/forbidden.

Each resource represents 1 worker, and each worker can only perform one task at a time, so I am trying to state that, for every resources, the cumsum of allocation can at max be 1.

It might be important to note that start is also a decision variable.

 % Constraint allocated to only one task at a time
    constraint forall(t in Resources)(
        cumulative(start, duration, [resource_allocation[t, r] | t in Tasks], 1)
    );

Doing so, I always end up with the following error

JC:70.12-82
  in call 'cumulative'
cumulative:21-3.49-7
  in binary '/\' operator expression
cumulative:25-3.49-7
  in if-then-else expression
cumulative:26-5.48-9
  in binary '/\' operator expression
cumulative:30-5.48-9
  in if-then-else expression
cumulative:47.7-32
  in call 'fzn_cumulative'
fzn_cumulative:4-9.20-17
  in let expression
fzn_cumulative:8-13.20-17
  in if-then-else expression
fzn_cumulative:10-17.19-17
  in let expression
fzn_cumulative:12.21-74
  in variable declaration for 'late'
  in call 'max'
    with i = <expression>
MiniZinc: evaluation error: arithmetic operation on infinite value
Process finished with non-zero exit code 1.

I need a little guidance, I looked in the source code of fzn_cumulative, but I don't get what is going on. Thanks !

Answer 1

You might consider to limit the domains of your decisions variables. int is unlimited (disregarding the limited number of bits per int) and may lead to overflow situations or complaints about infinite values.

include "globals.mzn";
set of int: Tasks = 1..3;
set of int: Resources = 1..3;
set of int: Durations = 1..10;
set of int: Times = 1..1000;

% Use this editor as a MiniZinc scratch book
array[Tasks, Resources] of var 0..1: resource_allocation; %Selection of resources per task.
array [Tasks] of var Times: start;
array [Tasks] of var Durations: duration;
array [Tasks] of set of Resources: resource_required = [{1,2},{2,3},{3}];
array [Tasks] of set of Resources: resource_forbidden = [{},{1},{1}];

% Mandatory & Forbidden constraint allocation
constraint forall(t in Tasks, r in resource_required[t])(resource_allocation[t,r]=1);
constraint forall(t in Tasks, r in resource_forbidden[t])(resource_allocation[t,r]=0);

% Constraint allocated to only one task at a time
% Changed "t in Resources" to "r in Resources"
    constraint forall(r in Resources)( 
        cumulative(start, duration, [resource_allocation[t, r] | t in Tasks], 1)
    );