Jooq "generateJooq" causing java.lang.ClassNotFoundException: jakarta.xml.bind.annotation.XmlSchema in Spring Boot App

Question

I am using Gradle 7.3.3 to build a Spring Boot Application that uses jooq to generate Table, POJO, and Record Classes from a pre-existing database schema. When attempting to upgrade jooqVersion from 3.15.5 to 3.16.0, :generateJooq returns the following error:

> Task :generateJooq FAILED
1 actionable task: 1 executed
Exception in thread "main" java.lang.NoClassDefFoundError: jakarta/xml/bind/annotation/XmlSchema
    at org.jooq.util.jaxb.tools.MiniJAXB.getNamespace(MiniJAXB.java:400)
    at org.jooq.util.jaxb.tools.MiniJAXB.addDefaultNamespace(MiniJAXB.java:188)
    at org.jooq.util.jaxb.tools.MiniJAXB.unmarshal0(MiniJAXB.java:175)
    at org.jooq.util.jaxb.tools.MiniJAXB.unmarshal(MiniJAXB.java:161)
    at org.jooq.codegen.GenerationTool.load(GenerationTool.java:1180)
    at org.jooq.codegen.GenerationTool.main(GenerationTool.java:203)
Caused by: java.lang.ClassNotFoundException: jakarta.xml.bind.annotation.XmlSchema
    at java.base/jdk.internal.loader.BuiltinClassLoader.loadClass(BuiltinClassLoader.java:606)
    at java.base/jdk.internal.loader.ClassLoaders$AppClassLoader.loadClass(ClassLoaders.java:168)
    at java.base/java.lang.ClassLoader.loadClass(ClassLoader.java:522)
    ... 6 more


Caused by: java.lang.ClassNotFoundException: jakarta.xml.bind.annotation.XmlSchema

:generateJooq worked fine in 3.15.5. We are requiring 3.16.0 as it (supposedly) allows DSL to manipulate PostGIS queries.

A number of posts have recommended this, but it has not worked in this case.

implementation 'jakarta.xml.bind:jakarta.xml.bind-api:3.0.1'
implementation 'org.glassfish.jaxb:jaxb-runtime:3.0.1'

I am currently using Azul Zulu version 15.0.5 (JDK 15), and the Jooq Plugin to Gradle:

import nu.studer.gradle.jooq.JooqEdition

plugins {
    id 'java'
    id 'jacoco'
    id 'maven-publish'
    id 'org.springframework.boot' version '2.3.1.RELEASE'
    id 'com.github.johnrengelman.shadow' version '5.2.0'
    id 'io.spring.dependency-management' version '1.0.9.RELEASE'
    id 'com.jfrog.artifactory' version '4.16.0'
    id 'nu.studer.jooq' version '6.0.1'
}

My Dependencies are as follows:

ext {
    assertjVersion = '3.22.0'
    awsSdkVersion = '1.11.812'
    awsLambdaEventsVersion = '2.2.9' //version 3.1.0 does not deserialize S3Event properly
    awsLambdaCoreVersion = '1.2.1'
    geojsonJacksonVersion = '1.14'
    lombokVersion = '1.18.22'
    mapstructVersion = '1.4.2.Final'
    postgresVersion = '42.3.1'
    slf4jVersion = '1.7.32'
    springCloudFunctionVersion = '3.0.6.RELEASE'
    springCloudVersion = '2.2.6.RELEASE'
    testNGVersion = '7.4.0'
    msDbSchemaVersion = '0.10.10'
    jooqVersion = '3.16.0'
}

dependencies {
    implementation("org.mapstruct:mapstruct:${mapstructVersion}")
    annotationProcessor("org.mapstruct:mapstruct-processor:${mapstructVersion}")
    annotationProcessor("org.projectlombok:lombok:${lombokVersion}")
    compileOnly("org.projectlombok:lombok:${lombokVersion}")
    implementation("org.springframework.cloud:spring-cloud-function-context")
    implementation("org.springframework.cloud:spring-cloud-starter-function-web")
    implementation("org.slf4j:slf4j-api:${slf4jVersion}")
    implementation("de.grundid.opendatalab:geojson-jackson:${geojsonJacksonVersion}")
    implementation 'jakarta.xml.bind:jakarta.xml.bind-api:3.0.1'
    implementation 'org.glassfish.jaxb:jaxb-runtime:3.0.1'

    implementation 'org.liquibase:liquibase-core'
    implementation("org.jooq:jooq:${jooqVersion}")

    jooqGenerator("org.postgresql:postgresql:${postgresVersion}")

    implementation('org.springframework.boot:spring-boot-starter-jooq')
    implementation("org.postgresql:postgresql:${postgresVersion}")

    implementation("com.amazonaws:aws-lambda-java-events:${awsLambdaEventsVersion}")
    implementation("com.amazonaws:aws-lambda-java-core:${awsLambdaCoreVersion}")
    implementation("com.amazonaws:aws-java-sdk-s3:${awsSdkVersion}")

    testImplementation('org.springframework.boot:spring-boot-starter-test') {
        exclude group: 'org.junit.vintage', module: 'junit-vintage-engine'
    }
    testImplementation("org.testng:testng:${testNGVersion}")
    testImplementation("org.assertj:assertj-core:${assertjVersion}")
}

Update: Using dependency insight shows that jakarta.xml.bind:jakarta.xml.bind-api is being forced down to 2.3.3, but nothing (as far as I can see) is providing the rule to do this.

$ ./gradlew --scan -q dependencyInsight --configuration jooqGenerator --dependency jakarta.xml.bind-api 
jakarta.xml.bind:jakarta.xml.bind-api:2.3.3 (selected by rule)
   variant "runtime" [
      org.gradle.status          = release (not requested)
      org.gradle.usage           = java-runtime (not requested)
      org.gradle.libraryelements = jar (not requested)
      org.gradle.category        = library (not requested)
   ]

jakarta.xml.bind:jakarta.xml.bind-api:3.0.0 -> 2.3.3
\--- org.jooq:jooq:3.16.3
     +--- org.jooq:jooq-codegen:3.16.3
     |    \--- jooqGenerator (requested org.jooq:jooq-codegen)
     \--- org.jooq:jooq-meta:3.16.3
          \--- org.jooq:jooq-codegen:3.16.3 (*)

(*) - dependencies omitted (listed previously)

Answer 1

Placing the io.spring.dependency-management into build isolation resolves the issue when using version 7.0 of the nu.studer.jooq plugin:

plugins {
    id 'java'
    id 'jacoco'
    id 'maven-publish'
    id 'org.springframework.boot' version '2.6.3'
    id 'com.github.johnrengelman.shadow' version '5.2.0'
    id 'io.spring.dependency-management' version '1.0.11.RELEASE' apply false
    id 'com.jfrog.artifactory' version '4.16.0'
    id 'nu.studer.jooq' version '7.0'
}

And then:

build {

    apply plugin: 'io.spring.dependency-management'

    dependencyManagement {
        imports {
            mavenBom "org.springframework.cloud:spring-cloud-function-dependencies:${springCloudFunctionVersion}"
        }
    }

}

This is because io.spring.dependency-management forces (by rule) the jakarta.xml.bind:jakarta.xml.bind-api version from 3.0.0 down to 2.3.3.