Music Visualizer using Processing

Question

I'm trying to create a music visualizer using Processing. My idea is to have a line, across the entire screen, that moves accordingly with a song.

This is what I have, right now

import ddf.minim.analysis.*;
import ddf.minim.*;

Minim minim;
AudioPlayer track;
AudioInput input;
FFT fft;
//AudioIn in;
String audioFileName = "dune.mp3";

void setup()
{
  //size(480, 320);
  fullScreen();
  noCursor();
  minim = new Minim(this);
  track = minim.loadFile(audioFileName, 2048);
  input = minim.getLineIn();

  fft = new FFT(input.bufferSize(), input.sampleRate());
}

void draw()
{
  background(0);
  stroke(255);

  fft.forward(input.mix);
 
  for (int i = 0; i < fft.specSize(); i++)
  {

    ellipse(i, 200, 7, fft.getBand(i)*10);
    //line(0, 200, 200, fft.getBand(i));

   
  }
}

So, my problems are:

1. the music that I'm loading, it's not working. (String audioFileName). Only the input, so when I talk to the microphone, works
2. I can't get a line, only the ellipse like the code

Does anyone knows how to solve this? Or has a good tutorial that I can follow?

Thank you

Answer 1

Your demo crashes on my Mac and will take me a while to debug. Perhaps the following demo which I copied from the web will get you started (see file header): http://code.compartmental.net/minim/minim_class_minim.html . It is heavily commented with several 'println' calls to hopefully give you some idea of how it works. You will need to create a 'data' folder in your Processing sketch folder and place a file named 'groove.mp3' inside the data folder in order to run it. I've tested it on my system and it seems to work ok. Does not use FFT.

/*
 This sketch demonstrates how to play a file with Minim using an AudioPlayer.
 It's also a good example of how to draw the waveform of the audio. Full documentation 
 for AudioPlayer can be found at http://code.compartmental.net/minim/audioplayer_class_audioplayer.html
 For more information about Minim and additional features, visit http://code.compartmental.net/minim/
 */

import ddf.minim.*;

Minim minim;
AudioPlayer player;

void setup() {
  size(512, 200);
  // we pass this to Minim so that it can load files from the data directory
  minim = new Minim(this);
  println("minim = ", minim);
  // loadFile will look in all the same places as loadImage does.
  // this means you can find files that are in the data folder and the 
  // sketch folder. you can also pass an absolute path, or a URL.
  player = minim.loadFile("groove.mp3");
  println("player = ", player);
}

void draw() {
  background(0);
  stroke(255);
  // draw the waveforms
  // the values returned by left.get() and right.get() will be between -1 and 1,
  // so we need to scale them up to see the waveform
  // note that if the file is MONO, left.get() and right.get() will return the same value
  for (int i = 0; i < player.bufferSize() - 1; i++) {
    float x1 = map( i, 0, player.bufferSize(), 0, width );
    float x2 = map( i+1, 0, player.bufferSize(), 0, width );
    line( x1, 50 + player.left.get(i)*50, x2, 50 + player.left.get(i+1)*50 );
    line( x1, 150 + player.right.get(i)*50, x2, 150 + player.right.get(i+1)*50 );
  }
  // draw a line to show where in the song playback is currently located
  float posx = map(player.position(), 0, player.length(), 0, width);
  stroke(0, 200, 0);
  line(posx, 0, posx, height);

  if ( player.isPlaying() ) {
    text("Press any key to pause playback.", 10, 20 );
  } else {
    text("Press any key to start playback.", 10, 20 );
  }
}

void keyPressed() {
  if ( player.isPlaying() ) {
    player.pause();
  }
  // if the player is at the end of the file,
  // we have to rewind it before telling it to play again
  else if ( player.position() == player.length() ) {
    player.rewind();
    player.play();
  } else {
    player.play();
  }
}

The following is a revision of your initial post along with the reference that I used to debug it. 'Input' is the microphone and 'track' is the file; you had it set up to use the microphone and I switched it to the file. Just like the example above you will need to create a data folder in the Processing sketch folder and insert a file named 'groove.mp3'.

/*
  Reference: https://github.com/ddf/Minim/blob/v2.2.2/examples/Analysis/SoundSpectrum/SoundSpectrum.pde
*/

import ddf.minim.analysis.*;
import ddf.minim.*;

Minim minim;
AudioPlayer track;
AudioInput input;
FFT fft;

String audioFileName = "groove.mp3";

void setup() {
  size(480, 320);
  noCursor();
  minim = new Minim(this);
  track = minim.loadFile(audioFileName, 1024);
  input = minim.getLineIn();
  fft = new FFT(track.bufferSize(), track.sampleRate());
  println(fft);
  track.loop();
}

void draw() {
  background(0);
  stroke(255);
  fft.forward(track.mix);
  for (int i = 0; i < fft.specSize(); i++) {
    ellipse(i, 200, 7, fft.getBand(i)*10);
    // line(0, 200, 200, fft.getBand(i));  //Unable to get this to work
  }
}