Plot Complex function in Gnuplot

Question

I have the following code for gnuplot:

set encoding utf8
set zlabel 'Im(z)'
set ylabel 'Re(z)'
unset key
set view map scale 1.2
set isosamples 500, 500
set samples 500
set size ratio 1 1,1
set style data lines
set title "Phase angle" 
set cblabel "Angulo de fase" 
set cblabel  offset character -2, 0, 0 font "" textcolor lt -1 rotate by -270
set cbrange [ -pi : pi ] noreverse nowriteback
set cbtics   ("0" -pi, "2π" pi)
set palette defined ( 0 0 1 1, 1 1 1 1 )
set xrange [-6:6] noreverse nowriteback
set yrange [-6:6] noreverse nowriteback
set palette positive nops_allcF maxcolors 0 gamma 1.5 color model HSV 
Hue(x,y) = (pi + atan2(y,x)) / (2*pi)
phase(x,y) = hsv2rgb( Hue(x,y), sqrt(x**2+y**2) )
f(x,y) = 1/((x+y*{0,1})-7)
rp(x,y) = real(f(x,y))
ip(x,y) = imag(f(x,y))
color(x,y) = hsv2rgb( Hue( rp(x,y), ip(x,y) ), abs(f(x,y)), 1)
splot '++' using 1:2:(color($1,$2)) with pm3d lc rgb variable

The problem is that I need to know the behavior of the function beyond the limit of 5, in this case the behavior in (7,0) or 7+0i

Answer 1

The sampling range is controlled separately from the plot axis range. It defaults to [-5:5], which is what you see in your current plot. To expand the sampling range and expand the displayed axis range also:

  set urange [-8:8]; set vrange [-8:8]
  set xrange [-10:10]; set yrange [-10:10]
  set tics rangelimit scale 0.0
  replot