Creating xsl:result-document with xpath 3.1 fn:transform using saxon 9.9 EE

Question

I'd like to create an output document using the xpath 3.1 fn:transform. Following is A.xsl. It creates A.xml when run directly (from oxygen):

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:math="http://www.w3.org/2005/xpath-functions/math"
    exclude-result-prefixes="xs math"
    version="3.0">
    
    <xsl:output name="xml" method="xml" indent="true" />
    
    <xsl:template name="xsl:initial-template">
        <xsl:message select="'A'"/>
        
        <xsl:result-document href="file:/C:/Work/test/A.xml" format="xml">
            <resultDoc>
                <text>The result of A.</text>
            </resultDoc>
        </xsl:result-document>
    </xsl:template>
</xsl:stylesheet>

Result: A.xml is created with the desired output:

<?xml version="1.0" encoding="UTF-8"?>
<resultDoc>
   <text>The result of A.</text>
</resultDoc>

Now, using the transform function to call A.xsl:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="xs"
    version="3.0">
    
    <xsl:output name="xml" method="xml" encoding="UTF-8" indent="true" />
    
    <!-- Global Constants -->
    
    <xsl:variable name="xsl-file-base" select="'file:/C:/Work/test/'" as="xs:string"/>
    <xsl:variable name="xsl-pipeline" select="'A.xsl'" as="xs:string"/>
    
    <!-- Entry Point -->
    
    <xsl:template name="xsl:initial-template">
        <xsl:iterate select="$xsl-pipeline">
            <xsl:variable name="file" select="$xsl-file-base || ." as="xs:string"/>
            
            <xsl:result-document href="file:/C:/Work/test/A.xml" format="xml">
                <xsl:sequence select="transform(map{'stylesheet-location' : $file})?output"/>
            </xsl:result-document>
        </xsl:iterate>       
    </xsl:template>
</xsl:stylesheet>

Result: A.xml is created but incomplete. Any help is appreciated.

<?xml version="1.0" encoding="UTF-8"?>

Answer 1

The result of the transform function is a map with an entry named output for the primary result document and further entries for secondary result documents. Your called stylesheet creates a secondary result with the URI file:/C:/Work/test/A.xml so

<xsl:sequence 
   select="transform(map{'stylesheet-location' : $file})('file:/C:/Work/test/A.xml')"/>

is more likely to produce an output.