Search code examples
autocompletezshtab-completionzsh-completion

How do I make a zsh function autocomplete as a file?

I use zsh and wrote a function to replace cd function. With some help I got it to work like I want it to (mostly). This is a followup to one of my other question. The function almost works like I want it to, but I still have some problems with syntax highlighting and autocompletion.

For the examples, lets say your directories look like this:

/
    a/
        b/
        c/
            d/
        some_dir/

I am also assuming the following code has been sourced:

cl () {
    local first=$( echo $1 | cut -d/ -f1 )
    if [ -d $first ]; then
        pushd $1 >/dev/null # If the first argument is an existing normal directory, move there
    else
        pushd ${PWD%/$first/*}/$1 >/dev/null # Otherwise, move to a parent directory or a child of that parent directory
    fi
}
_cl() {
    _cd
    pth=${words[2]}
    opts=""
    new=${pth##*/}
    local expl
    # Generate the visual formatting and store it in `$expl`
    _description -V ancestor-directories expl 'ancestor directories'
    [[ "$pth" != *"/"*"/"* ]] && middle="" || middle="${${pth%/*}#*/}/"
    if [[ "$pth" != *"/"* ]]; then
        # If this is the start of the path
        # In this case we should also show the parent directories
        local ancestor=$PWD:h
        while (( $#ancestor > 1 )); do
            # -f: Treat this as a file (incl. dirs), so you get proper highlighting.
            # -Q: Don't quote (escape) any of the characters.
            # -W: Specify the parent of the dir we're adding.
            # ${ancestor:h}: The parent ("head") of $ancestor.
            # ${ancestor:t}: The short name ("tail") of $ancestor.
            compadd "$expl[@]" -fQ -W "${ancestor:h}/" - "${ancestor:t}"
            # Move on to the next parent.
            ancestor=$ancestor:h
        done
    else
        # $first is the first part of the path the user typed in.
        # it it is part of the current direoctory, we know the user is trying to go back to a directory
        first=${pth%%/*}
        # $middle is the rest of the provided path
        if [ ! -d $first ]; then
            # path starts with parent directory
            dir=${PWD%/$first/*}/$first
            first=$first/
            # List all sub directories of the $dir/$middle directory
            if [ -d "$dir/$middle" ]; then
                for d in $(ls -a $dir/$middle); do
                    if [ -d $dir/$middle/$d ] && [[ "$d" != "." ]] && [[ "$d" != ".." ]]; then
                        compadd "$expl[@]" -fQ -W $dir/ - $first$middle$d
                    fi
                done
            fi
        fi
    fi
}
compdef _cl cl

The problem: When going back to a parent directory, complition mostly works. But when you go to a child of the parent directory, the suggestion is wrong (the full path you typed is displayed, not just the child directory).

Example:

$ cd /a/c/d
$ cl a/[tab] # What it currently displays
a/b   a/c  a/some_dir
$ cl a/[tab] # What I want it to display
b     c    some_dir

How do I get it to display the second suggestions?

Solution

  • You can let a completion be displayed in whatever way you want by supplying a display string array with the -d option:

    local -a disp
# (N) gives an empty array when there are no matches, rather than an error.
# (:t) returns the last segment of each path.
for d in $dir/$middle*(N:t); do
  disp=( "$d" )  
  compadd "$expl[@]" -fQ -W $dir/ -d disp - $first$middle$d
done

    Documentation: