network interface conflicts with subnet ID - Terraform AWS provider

Question

I am trying to create an instance within a custom VPC using Terraform while following an online training. here is what I have come up with:

 resource "aws_vpc" "main" {
  cidr_block = "10.0.0.0/16"
  tags = {
      name = "prod-VPC"
  }
}
# create subnet
resource "aws_subnet" "subnet1" {
  vpc_id     = aws_vpc.main.id
  cidr_block = "10.0.1.0/24"

  tags = {
    Name = "TF-Subnet"
  }
}

#create IG

resource "aws_internet_gateway" "gw" {
  vpc_id = aws_vpc.main.id
}

#create route table
resource "aws_route_table" "r" {
  vpc_id = aws_vpc.main.id

  route {
    cidr_block = "0.0.0.0/0"
    gateway_id = aws_internet_gateway.gw.id
  }
}

#associate subnet to route table
resource "aws_route_table_association" "a" {
  subnet_id      = aws_subnet.subnet1.id
  route_table_id = aws_route_table.r.id
}

#create SG

resource "aws_security_group" "allow_SSH_HTTP" {
  name        = "allow_SSH_HTTP"
  description = "Allow TLS inbound traffic"
  vpc_id      = aws_vpc.main.id

  ingress {
    description = "SSH"
    from_port   = 22
    to_port     = 22
    protocol    = "tcp"
    cidr_blocks = ["0.0.0.0/0"]
  }
  ingress {
    description = "HTTP"
    from_port   = 80
    to_port     = 80
    protocol    = "tcp"
    cidr_blocks = ["0.0.0.0/0"]
  }
  egress {
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }

  tags = {
    Name = "allow_SSH_HTTP"
  }
}

#create a network interface with IP
resource "aws_network_interface" "NI" {
  subnet_id       = aws_subnet.subnet1.id
  private_ips     = ["10.0.1.50"]
  security_groups = [aws_security_group.allow_SSH_HTTP.id]
}

# assign elastic IP to interface

resource "aws_eip" "one" {
  vpc                       = true
  network_interface         = aws_network_interface.NI.id
  associate_with_private_ip = "10.0.1.50"
  depends_on = [aws_internet_gateway.gw]
}

# create EC2 install Apache


resource "aws_instance" "server" {
  ami           = "ami-0ebc1ac48dfd14136"
  instance_type = "t2.micro"
  subnet_id     = aws_subnet.subnet1.id
  key_name      = "RPkey"
    
network_interface {
        device_index = 0
        network_interface_id = aws_network_interface.NI.id
    }

user_data      = <<-EOF
                #! bin/bash
                sudo yum install apache2 -y
                sudo service apache2 start
                echo "<h1>deployed by Terraform</h1>" >> /var/www/html/index.html
                EOF

    tags = {
    Name = "TFserver"
  }
}

The "plan" step succeeds but "apply" results in the following error:

    Do you want to perform these actions?   Terraform will perform the actions described above.   Only 'yes' will be accepted to approve.
    
      Enter a value: yes
    
    aws_vpc.main: Creating... aws_vpc.main: 
Creation complete after 2s [id=vpc-0a79f98c26ff9ac2f] aws_internet_gateway.gw: 
Creating... aws_subnet.subnet1: Creating... aws_security_group.allow_SSH_HTTP: 
Creating... aws_internet_gateway.gw: Creation complete after 1s [id=igw-0f3fb6801ec48275c] 
aws_subnet.subnet1: Creation complete after 1s [id=subnet-0b89ab7649c381937] 
aws_route_table.r: Creating... aws_route_table.r: Creation complete after 1s [id=rtb-0a4dbfeb0e54c8a4c] 
aws_route_table_association.a: Creating... aws_route_table_association.a: Creation complete after 0s [id=rtbassoc-0e52de7724851ac43] 
aws_security_group.allow_SSH_HTTP: Creation complete after 2s [id=sg-0aeb94bfefe5259df] 
aws_network_interface.NI: Creating... aws_network_interface.NI: Creation complete after 3s [id=eni-0542d5572bd70097e] 
aws_eip.one: Creating... aws_eip.one: Creation complete after 1s [id=eipalloc-007935cd406602652]
    
    Error: "network_interface": conflicts with subnet_id
    
      on main.tf line 106, in resource "aws_instance" "server":  106: resource "aws_instance" "server" {

At this point things get messed up and even the destroy command does not work. I have seen in a few example that people tend to specify the AZ while creating the subnet and the instance. I have tried to create a subnet and then ensured that the instance is created in the specified subnet. I an unable to figure out what causes the conflict error with subnet and network interface.

Terraform version: v0.13.0 Provider Version: v3.1.0

Answer 1

You shouldn't have subnet_id when you use network_interface. The reason is that the instance will be create in the subnet where the network interface is.

Therefore, your instance definition should be (subnet_id removed):

resource "aws_instance" "server" {
  ami           = "ami-0ebc1ac48dfd14136"
  instance_type = "t2.micro"
 
  key_name      = "RPkey"
    
  network_interface {
        device_index = 0
        network_interface_id = aws_network_interface.NI.id
    }

  user_data      = <<-EOF
                #! bin/bash
                sudo yum install apache2 -y
                sudo service apache2 start
                echo "<h1>deployed by Terraform</h1>" >> /var/www/html/index.html
                EOF

    tags = {
    Name = "TFserver"
  }
}