Passing different parameters to created jobs

Question

On Jenkins, using Job DLS plugin, I'm trying to prepare one script which will create jobs configured for different environments (dev and preprod). Depends on for which environments this job has to run, different parameters are needed.

In this situation how to define, in the shortest way, that parameters for dev environment include the same as preprod parameters plus additionally i.e. 2 more?

An example of the code which I use is presented below.

def environments = ["DEV", "PREPROD"]
def names = ["name1", "name2", "name3"]

def jobParameters = {
  string {
    name("browser")
    defaultValue("CHROME")
    description("Browser on which one tests will run")
    trim(true)
  }
  string {
    name("parameter1")
    defaultValue("")
    description("")
    trim(true)
  }
}

def jobParametersDev = {
  jobParameters
  string {
    name("parameter2")
    defaultValue("")
    description("")
    trim(true)
  }
  string {
    name("parameter3")
    defaultValue("")
    description("")
    trim(true)
  }
}


def createJob(name, env, runCommand, jobParameters) {
  job("Job-${-> name}-${-> env}") {
    description("My first job for ${-> name}")
    parameters(jobParameters)
    steps {
      shell {
        command(runCommand)
      }
    }
  }
}


for (name in names) {
  for (env in environments) {
    if (env == 'DEV') {
      def runCommand = "python35 -u ./TestSuite-${-> name}.py %parameter1% %parameter2%,%parameter3% %browser%"
      createJob(name, env, runCommand, jobParametersDev)
    } else {
      def runCommand = "python35 -u ./TestSuite-${-> name}.py %parameter1% ${-> env} %browser%"
      createJob(name, env, runCommand, jobParameters)
    }
  }
}

To summarise - the last thing which I tried is:

def jobParametersDev = {
  jobParameters
  ...
}

But it doesn't work... Only values for jobParametersDev are visible.

How to add these values? If it's not necessary I don't want to double the same code.

I will be really grateful for any help.

Answer 1

You can not simply call one closure within another. But you can chain method calls. You just need to pass the job reference.

def generateParameters = { job ->
  job.parameters {
    stringParam('param3', '', '')
    // more params here...
  }
}

def generateDevParameters = { job ->
  generateParameters(job)
  job.parameters {
    stringParam('param4', '', '')
    // more params here...
  }
}

def createJob(name, generateParameters) {
  def j = job(name) {
      // more config here...
  }
  generateParameters(j)
}

createJob('test1', generateParameters)
createJob('test2', generateDevParameters)