How to implement TemporalAdjuster in Clojure

Question

Clojure newbie, here.

I'm trying to implement a TemporalAdjuster in Clojure. I have the following:

(ns pto-calculator.logic.pay-periods
  (:require [java-time :as j]))

(def next-pay-period
  (reify java.time.temporal.TemporalAdjuster
    (adjustInto [this temporal]
      (let [local-date (java.time.LocalDate/from temporal)
            day-of-month (.getDayOfMonth local-date)]
        (if (< 14 day-of-month)
          (j/plus local-date (j/days (- 14 day-of-month)))
          (j/adjust local-date :last-day-of-month))))))

(defn get-next-pay-period [date]
  (j/adjust date next-pay-period))

And I call it like this:

(ns pto-calculator.core
  (:require [pto-calculator.logic.pay-periods :as p]
            [java-time :as j])
  (:gen-class))

(defn -main
  [& args]
  (p/get-next-pay-period j/local-date))

Today is March 2nd, so I expect get-next-pay-period to return March 14th, however, I'm getting an exception instead:

Caused by: java.lang.ClassCastException: java_time.local$local_date cannot be cast to java.time.temporal.Temporal
    at java_time.adjuster$adjust.invokeStatic(adjuster.clj:64)
    at java_time.adjuster$adjust.doInvoke(adjuster.clj:40)
    at clojure.lang.RestFn.invoke(RestFn.java:425)
    at pto_calculator.logic.pay_periods$get_next_pay_period.invokeStatic(pay_periods.clj:19)
    at pto_calculator.logic.pay_periods$get_next_pay_period.invoke(pay_periods.clj:18)

My confusion is this: (j/local-date) returns an instance of java.time.LocalDate, which is a Temporal (according to the docs). So why wouldn't this work?

I've also tried:

(defn get-next-pay-period [^java.time.temporal.Temporal date]
...

But in that case I get this error:

java_time.local$local_date cannot be cast to java.time.temporal.Temporal

Is there a difference between java_time.local$local_date and java.time.LocalDate?

Answer 1

You aren't invoking java-time/local-date in your core namespace. You are passing a function to get-next-pay-period.

Instead of:

(defn -main
  [& args]
  (p/get-next-pay-period j/local-date))

Try:

(defn -main
  [& args]
  (p/get-next-pay-period (j/local-date)))