Include a range of "possible" dates in a SPARQL filter

Question

I'm working on a DBPedia project to locate female singers who would have been active during the 1960s (approx).

Unfortunately when I try to select a range of singers who were active from 1955 - 1972 I miss out on singers who were active before 1955 (the results negate some singers, for instance Umm Kulthum who was active from 1925-1973).

My code is below, and shows where the filter is only including artists who were active exclusively for this date range. I want to create a filter that says "give me all singers who would have been musically active during the this date range in particular, but also include those who might have been active from a period before and including this date range"? I don't want those that were only active before this date range.

PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX dbp: <http://dbpedia.org/resource/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX dbc: <http://dbpedia.org/resource/Category:>

SELECT distinct ?name ?person ?thumbnail ?birthDate ?active
 where {
?person foaf:name ?name . 
?person dct:subject ?subject.
?person dbo:birthDate ?birthDate.
OPTIONAL {?person dbo:thumbnail ?thumbnail}
OPTIONAL {?person dbo:activeYearsStartYear ?active}

{ ?person a dbo:MusicalArtist . 
filter exists {?person 
dct:subject/skos:broader*dbc:Female_singers_by_nationality}}

filter (?active > '1955-04-18T22:29:33.667Z'^^xsd:dateTime && ?active < 
'1974-01-01T21:37:37.708Z'^^xsd:dateTime)} order by ?active

Answer 1

One solution is to also check the reverse in your filter using a boolean or. Like this:

SELECT distinct ?name ?person ?thumbnail ?birthDate ?activeStart ?activeEnd 
where {
  ?person foaf:name ?name . 
  ?person dct:subject ?subject.
  ?person dbo:birthDate ?birthDate. 
  ?person dbo:activeYearsStartYear ?activeStart. 
  ?person dbo:activeYearsEndYear ?activeEnd 
  OPTIONAL {?person dbo:thumbnail ?thumbnail }
  { ?person a dbo:MusicalArtist . 
    filter exists {
        ?person dct:subject/skos:broader* dbc:Female_singers_by_nationality
    }
  } 
  BIND('1955-04-18T22:29:33.667Z'^^xsd:dateTime as ?startPeriod) 
  BIND('1974-01-01T21:37:37.708Z'^^xsd:dateTime as ?endPeriod) 
  filter ( (?activeStart > ?startPeriod && ?activeStart < ?endPeriod) 
         || (?activeStart < ?startPeriod && ?activeEnd > ?startPeriod))
} 
order by ?activeStart