vb.Net- Named Pipes - NamedPipeServerStream - StackOverflowException

Question

I'm trying to use named pipes to communicate between a windows service and a WPF application, both written in VB.Net. The windows service is always running.

However after several hours of running the WPF application a StackOverflowException is thrown.

PipeServerThread() in the WPF application is the only function being called repeatedly in the managed stack at the time of the exception (I tracked this down using WinDbg).

The service contains the NamedPipeClientStream, The application contains the NamedPipeServerStream.

When the client and server communicate, the server reads the final client response after a few checks, then passes the clientstring to a function elsewhere in the code.

The pipeserver is then flushed, closed and disposed.

The PipeServerThread() is then called again to create another pipe server for communication. Note this PipeServerThread() is called repeatedly.

Could anyone shed light on what in the code is eventually causing the StackOverflowException to occur?

PipeServer :

Dim PipeServers(1) As Thread
PipeServers(1) = New Thread(AddressOf PipeServerThread)
PipeServers(1).IsBackground = True
PipeServers(1).Start()

Private Sub PipeServerThread()

    Dim ps = New System.IO.Pipes.PipeSecurity

    Try
        ps.AddAccessRule(New System.IO.Pipes.PipeAccessRule("Users", System.IO.Pipes.PipeAccessRights.FullControl, System.Security.AccessControl.AccessControlType.Allow))
        ps.AddAccessRule(New System.IO.Pipes.PipeAccessRule("CREATOR OWNER", System.IO.Pipes.PipeAccessRights.FullControl, System.Security.AccessControl.AccessControlType.Allow))
        ps.AddAccessRule(New System.IO.Pipes.PipeAccessRule("SYSTEM", System.IO.Pipes.PipeAccessRights.FullControl, System.Security.AccessControl.AccessControlType.Allow))

        Dim pipeserver = New System.IO.Pipes.NamedPipeServerStream("testpipe", Pipes.PipeDirection.InOut, 10, Pipes.PipeTransmissionMode.Byte, Pipes.PipeOptions.None, 4024, 4024, ps)

        Debug.WriteLine("Pipeserver waiting for connection")
        pipeserver.WaitForConnection()
        Try
            'Debug.WriteLine("Pipeserver now within Try block.")
            Dim ss As New StreamString(pipeserver)
            'This server writes to pipe immediately on connection
            Debug.WriteLine("Server now writing to Pipe")
            ss.WriteString("Hello Client. Who are you?")                                            'Action 1 - server writes to Pipe

            'Response from client is read
            Dim ClientName As String = ss.ReadString                                                'Action 4 - server reads from Pipe
            Debug.WriteLine("Client's name is: " & ClientName)
            If ClientName = "PipeWriterService" Then
                'The client is the PipeWriterService
                'Tell it what state is being requested
                ss.WriteString(RequestedCommState)                                                  'Action 5 (if) - server writes to Pipe
            Else
                'The client is someting else
                ss.WriteString("wrong client")                                                      'Action 5 (else) - server writes to Pipe
            End If

            Dim ClientResponse As String = ss.ReadString()
            Debug.WriteLine("Server has read client Response as: " & ClientResponse)                'Action 8 - server reads from Pipe
            DeviceInfo.Dispatcher.BeginInvoke(Windows.Threading.DispatcherPriority.Normal, New OneArgDelegate3(AddressOf ProcessPipeString), ClientResponse)
        Catch ex As Exception
            Debug.WriteLine("Error is Server Try block: " & ex.Message)
        End Try
        pipeserver.Flush()
        pipeserver.Close()                                                                          'Action 9 - server closes Pipe
        pipeserver.Dispose()
        Debug.WriteLine("PipeServer now closed")
    Catch ex As Exception

    End Try

    Call PipeServerThread()
End Sub

PipeClient :

    Private Sub PipeWriter(StringToWrite As String)
    Dim pipeClient As New NamedPipeClientStream(".", "testpipe", PipeDirection.InOut, PipeOptions.None)
    Try
        pipeClient.Connect(50)
        Dim ss As New StreamString(pipeClient)
        'Once a connection is established, Server will write to pipe first
        'This is read by the client in the line below
        Debug.WriteLine("First string from Server: " & ss.ReadString())                             'Action 2: Client Reads from Pipe
        'Server is now waiting. This client responds with its name
        ss.WriteString("PipeWriterService")                                                           'Action 3: Client Writes to Pipe
        'Server will respond again
        'This is read by the client in the line below
        RequestedCommState = ss.ReadString()                                                    'Action 6: Client reads from Pipe
        Debug.WriteLine("Second string from Server: " & RequestedCommState)
        'This response contains the desired 3G comm status from the server
        'Server is now waiting. This client responds with whatever it wants to say to server
        ss.WriteString(StringToWrite)                                                               'Action 7: Client writes to Pipe
    Catch ex As Exception
        Debug.WriteLine("Error in PipeWriter. Error is: " & ex.Message)
    End Try

End Sub

Answer 1

Probably you already resolved the problem at this point.

Anyway the problem is re recursive call at PipeServerThread(). Everytime you call it, the size of the stack is raised to holds the local variables and the return address of the function.

You have to get rid to the recursive call and put the function body in a loop.