How can an abstract implement an interface?

Question

I have a common interface that describes access to the output stream like this:

interface IOutput {
    function writeInteger(aValue:Int):Void;
}

And I have an abstract implementation of this interface based on standard haxe.io.BytesOutput class:

abstract COutput(BytesOutput) from BytesOutput {
    public inline function new(aData:BytesOutput) {
        this = aData;
    }
    public inline function writeInteger(aValue:Int):Void {
        this.writeInt32(aValue);
    }
}

Though this abstract is truly implementing interface described above there's no direct reference to interface and when I'm trying to use it like this:

class Main {
    public static function out(aOutput:IOutput) {
        aOutput.writeInteger(0);
    }
    public static function main() {
        var output:COutput = new BytesOutput();
        out(output); // type error
    }
}

Compiler throws an error: COutput should be IOutput. I can solve this problem only through using common class that wraps BytesOutput and implements IOutput.

My question is how to show the Haxe compiler that the abstract implements the interface.

Answer 1

Abstracts can't implement interfaces because they're a compile-time feature and don't exist at runtime. This conflicts with interfaces, they do exist at runtime and dynamic runtime checks like Std.is(something, IOutput) have to work.

Haxe also has a mechanism called structural subtyping that can be used as an alternative to interfaces. With this approach, there's no need for an explicit implements declaration, it's good enough if something unifies with a structure:

typedef IOutput = {
    function writeInteger(aValue:Int):Void;
}

Unfortunately, abstracts aren't compatible with structural subtyping either due to the way they're implemented.

---

Have you considered using static extensions instead? At least for your simple example, that seems like the perfect solution for making a writeInteger() method available for any haxe.io.Output:

import haxe.io.Output;
import haxe.io.BytesOutput;
using Main.OutputExtensions;

class Main {
    static function main() {
        var output = new BytesOutput();
        output.writeInteger(0);
    }
}

class OutputExtensions {
    public static function writeInteger(output:Output, value:Int):Void {
        output.writeInt32(value);
    }
}

You could even combine this with structural subtyping so writeInteger() becomes available on anything that has a writeInt32() method (try.haxe link):

typedef Int32Writable = {
    function writeInt32(value:Int):Void;
}