Learning recursion schemes in Haskell by TicTacToe

Question

Looking around, I noticed that recursion schemes are quite a general concept and I wanted to learn by experiencing it first hand. So I started implementing a minimax algorithm for TicTacToe. Here is a small snippet that sets the stage. Feel free to skip it, since it's just a basic implementation for completeness or read in an online IDE

{-# LANGUAGE DeriveFunctor #-}
import Data.Maybe
import Data.Sequence hiding (zip, filter, length)
import Data.Foldable
import Data.Monoid
import Control.Arrow

data Player = Cross | Nought deriving (Eq, Show)
type Cell = Maybe Player
data Board = Board { getPlayer :: Player, getCells :: Seq Cell }
type Move = Int

(!?) :: Seq a -> Move -> a
s !? m = index s m
showCell :: Cell -> String
showCell Nothing = " "
showCell (Just Cross) = "x"
showCell (Just Nought) = "o"
instance Show Board where
    show (Board p cells) = "+---+---+---+\n"
                        ++ "| " ++ showCell (cells !? 0)
                           ++ " | " ++ showCell (cells !? 1)
                               ++ " | " ++ showCell (cells !? 2) ++ " |\n"
                        ++ "+---+---+---+\n"
                        ++ "| " ++ showCell (cells !? 3)
                           ++ " | " ++ showCell (cells !? 4)
                               ++ " | " ++ showCell (cells !? 5) ++ " |\n"
                        ++ "+---+---+---+\n"
                        ++ "| " ++ showCell (cells !? 6)
                           ++ " | " ++ showCell (cells !? 7)
                               ++ " | " ++ showCell (cells !? 8) ++ " |\n"
                        ++ "+---+---+---+\n"
                        ++ "It's " ++ show p ++ "'s turn\n"

other :: Player -> Player
other Cross = Nought
other Nought = Cross

-- decide on a winner. The first found winner is taken, no matter if more exist
decide :: Board -> Maybe Player
decide (Board p cells) = getAlt $
                         isWinner 0 1 2 <> isWinner 3 4 5 <> isWinner 6 7 8 <>
                         isWinner 0 3 6 <> isWinner 1 4 7 <> isWinner 2 5 8 <>
                         isWinner 0 4 8 <> isWinner 2 4 6 where
    sameAs :: Cell -> Cell -> Cell
    sameAs (Just Cross) (Just Cross) = Just Cross
    sameAs (Just Nought) (Just Nought) = Just Nought
    sameAs _ _ = Nothing
    isWinner a b c = Alt $ (cells !? a) `sameAs` (cells !? b) `sameAs` (cells !? c)

initialState :: Board
initialState = (Board Cross (fromList $ map (const Nothing) [0..8]))

findMoves :: Board -> [Move]
findMoves (Board p cells) = map fst $ filter (isNothing . snd) $ zip [0..] $ toList cells

applyMove :: Board -> Move -> Board
applyMove (Board player cells) move = Board (other player) (update move (Just player) cells)

data MinimaxRating = Loss | Draw | Win deriving (Eq, Ord, Show)
invertRating Win = Loss
invertRating Draw = Draw
invertRating Loss = Win

Now, for the fun parts. I've come up with the following type to define my game tree:

-- a game tree is a tree with a current board
-- and a list of next boards tagged with moves
data GameTreeF b m f = Tree b [(m, f)]
    deriving (Functor)
type GameTree b m = Fix (GameTreeF b m)

and, easily enough, we can use an anamorphism to represent expanding a game by all legal moves

fullGameTree :: Board -> GameTree Board Move
fullGameTree = ana phi where
    phi board = Tree board $ map (id &&& applyMove board) (findMoves board)

and the minimax algorithm is represented as a catamorphism which we can write like so

-- given a game tree to explore, finds the best rating and a
-- move sequence that results in it
minimax :: GameTree Board Move -> (MinimaxRating, [Move])
minimax = cata phi where
    mergeInMove (m, (r, ms)) = (invertRating r, m:ms)
    compareMoves (m, ms) (n, ns) = compare m n <> compare (length ns) (length ms)
    phi (Tree board []) = (Draw, []) -- no legal moves is a draw
    phi (Tree board moves) = case decide board of
        Just winner | winner == getPlayer board -> (Win, []) -- we win
        Just winner                             -> (Loss, []) -- they win
        Nothing -> maximumBy compareMoves $ map mergeInMove moves

For my question: I now want to construct a GameTree that has tagged at each node the minimax result. So what I'm searching for, I believe is this function:

-- tag each node with the result of minimax for its subtree
computeKITree :: GameTree Board Move -> GameTree (Board, MinimaxRating, [Move]) Move

I just can't figure out how to write this function with recursion schemes. Can someone help me out here?

Answer 1

In minimax you have your minimax algebra phi :: GameTreeF Board (MinimaxRating, [Move]) -> (MinimaxRating, [Move]).

In computeKITree, which is going to be a cata, you need psi :: GameTreeF Board (GameTree (Board, ..., ...) Move) -> GameTree (Board, ..., ...) Move.

psi can use phi to compute the minimax, and then wrap everything in a GameTreeF.

We must transform the argument of psi to an argument of phi:

adaptPhi :: GameTreeF Board (GameTree (Board, ..., ...) Move) -> GameTreeF Board (..., ...)

That looks like a nice fmap! (Exercise for the reader.)

Once you have that...

computeKITree :: GameTree Board Move -> GameTree (Board, MinimaxRating, [Move]) Move
computeKITree = cata psi where
  psi t@(GameTree b ts) =
    let (rating, ms) = phi (adaptPhi t) in
    Fix (GameTree (b, rating, ms) ts)