Merging and inheriting parameters

Using xslt version 3.0 (saxon):

I have something like the following

<root>
  <template ID='1'>
    <params>
      <a>1</a>
      <b>1</b>
    </params>
  </template>

  <document1 templateID='1'>
    <params>
      <b>4</b>
      <c>5</c>
    </params>
  </document1>

</root>

Basicly I need to convert into something like

  <root>
    <document1 templateID='1'>
      <params>
        <a>1</a>
        <b>4</b>
        <c>5</c>
      </params>
    </document1>
  </root>

In the example parameter a is inherited from the template while parameter b is overwritten by the document itself and parameter c is not known or set in the template. It is akin to inheritance or how css work. I hope you get the idea. Before starting the task I thought this should not be too difficult (and still hoping Im just overlooking something).

I have tried something with concat'ing the two nodeset (using nodeset1 , nodeset2 to preserve the order) and using a preceding-sibling name based 'select'/'filtering' - but this strategy seems not to work as it seems they are not actual siblings. Could this be done with a clever group-by ? Can it be done at all ? (I think it can)

I am using xslt version 3.0 (saxon)

Solution

I think you want to group or merge, merging in XSLT 3 would be

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="#all"
    version="3.0">

  <xsl:output indent="yes"/>

  <xsl:mode on-no-match="shallow-copy"/>

  <xsl:key name="template-by-id" match="template" use="@ID"/>

  <xsl:template match="template"/>

  <xsl:template match="*[@templateID]/params">
      <xsl:copy>
          <xsl:merge>
              <xsl:merge-source name="template" select="key('template-by-id', ../@templateID)/params/*">
                  <xsl:merge-key select="string(node-name())"/>
              </xsl:merge-source>
              <xsl:merge-source name="doc" select="*">
                  <xsl:merge-key select="string(node-name())"/>
              </xsl:merge-source>
              <xsl:merge-action>
                  <xsl:copy-of select="(current-merge-group('doc'), current-merge-group('template'))[1]"/>
              </xsl:merge-action>
          </xsl:merge>
      </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/jyH9rN8/

grouping would be

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="#all"
    version="3.0">

  <xsl:output indent="yes"/>

  <xsl:mode on-no-match="shallow-copy"/>

  <xsl:key name="template-by-id" match="template" use="@ID"/>

  <xsl:template match="template"/>

  <xsl:template match="*[@templateID]/params">
      <xsl:copy>
          <xsl:for-each-group select="key('template-by-id', ../@templateID)/params/*, *" group-by="node-name()">
              <xsl:copy-of select="head((current-group()[2], .))"/>
          </xsl:for-each-group>
      </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/jyH9rN8/1

I think, as xsl:merge requires input to be sorted on any merge key or to sort the input first, the grouping above is easier and more reliable, unless your params child elements are really named with sorted letters or words from the alphabet.