Number of triples of specific group instances?

Question

I have found another problem in SPARQLing dbpedia. I am trying to get number of triples for specific group of class instances.

Number of triples of class Politician:

 SELECT * WHERE {?s ?p ?o FILTER (?s = dbo:Politician OR ?o = dbo:Politician)} 

But what about summary number of all triples for a specific group of politicians? For example number of triples of german politician. How is possible to get?

Thank you for your help!

Answer 1

revised answer

This will get the count of entities who are described as being Politicians from Germany —

SELECT COUNT(*) 
  { ?s a               dbo:Politician . 
    ?s dbo:nationality dbr:Germany . 
  }

— and this will get the count of all records where those entities who are described as being Politicians from Germany appear as Subject —

SELECT COUNT(*) 
  { ?s a               dbo:Politician . 
    ?s dbo:nationality dbr:Germany . 
    ?s ?p              ?o .
  }

It is possible that you're looking for a bit more info, to include all records where the entities who are described as being Politicians from Germany appears as either Subject or Object (not just as Subject) —

SELECT COUNT(*) 
  { { ?s a               dbo:Politician . 
      ?s dbo:nationality dbr:Germany . 
      ?s ?p              ?o . 
    }
  UNION
    { ?o a               dbo:Politician . 
      ?o dbo:nationality dbr:Germany . 
      ?s ?p              ?o . 
    }
  }

---

original answer

I think you are currently aiming for this, which counts all triples with dbo:Politician as either Subject or Object (which is currently 41105, without timeout), but note that this query doesn't count "entities which are politicians" which is (I think) what you're really after!

SELECT ( COUNT ( * ) AS ?NumberOfTriples ) 
WHERE
  { { dbo:Politician ?p ?o }
    UNION
    { ?s ?p dbo:Politician } 
  }

If you want to count the number of "entities which are politicians" (i.e., rdf:type dbo:Politician) (currently 41078), you need a different query, like this --

SELECT ( COUNT ( DISTINCT ?s ) AS ?NumberOfPoliticians ) 
WHERE
  { ?s rdf:type dbo:Politician } 

This should be clarified by a look at the { dbo:Politician ?p ?o } triples --

SELECT *
WHERE
  { dbo:Politician ?p ?o }