MQTT code stops working after a couple of hours

Question

Made some code for a NodeMCU in the Arduino IDE to push a button using MQTT. The code works perfectly fine for some time, but after a couple of hours it will not respond anymore.

The code is very frankenstein, since I am a mega rookie, and is as follows:

#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <Servo.h>

const char* ssid = "ap_name"; //change
const char* password =  "ap_pw"; //change
const char* mqttServer = "server_ip"; //change
const int mqttPort = 1883; 
const char* mqttUser = "server_name"; //change
const char* mqttPassword = "server_pw"; //change

WiFiClient espClient;
PubSubClient client(espClient);

Servo servo;

void setup() {
  Serial.begin(115200); 
  WiFi.begin(ssid, password);

  servo.attach(D4);
  servo.write(70);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.println("Connecting to WiFi..");
  }
  Serial.println("Connected to the WiFi network");

  client.setServer(mqttServer, mqttPort);
  client.setCallback(callback);

  while (!client.connected()) {
    Serial.println("Connecting to MQTT...");

    if (client.connect("ESP8266Client", mqttUser, mqttPassword )) {

      Serial.println("connected");  

    } else {

      Serial.print("failed with state ");
      Serial.print(client.state());
      delay(2000);

    }
  }

  client.publish("esp/test", "Hello from ESP8266");
  client.subscribe("esp/test");

}

void callback(char* topic, byte* payload, unsigned int length) {

  Serial.print("Message arrived in topic: ");
  Serial.println(topic);

  Serial.print("Message:");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }

  if(*payload == 49){
    rotServo();
    Serial.println();
    Serial.print("Roterar servo");
    delay(3000);
    client.publish("esp/test", "0");
  }

  Serial.println();
  Serial.println("-----------------------");

}

void rotServo(){
  servo.attach(D4);
  servo.write(70);
  delay(1000);
  servo.write(175);
  delay(2000);
  servo.write(70);
  delay(3000);
  servo.detach();
}

void loop() {
  client.loop();
}

Anyone that would know what might be causing it to stop working?

Answer 1

It could be because, you never reconnect if your client ever gets disconnected.

See the example here for more details, but here is the reconnect function from the example and how it is called in the loop. You would need to tailor it to suite your application.

void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Create a random client ID
    String clientId = "ESP8266Client-";
    clientId += String(random(0xffff), HEX);
    // Attempt to connect
    if (client.connect(clientId.c_str())) {
      Serial.println("connected");
      // Once connected, publish an announcement...
      client.publish("outTopic", "hello world");
      // ... and resubscribe
      client.subscribe("inTopic");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}


void loop() {

  if (!client.connected()) {
    reconnect();
  }
  client.loop();
  ...
}

On another note, while I don't think it would cause your specific problem, in your callback, you just compare the contents of the payload to the number 49.

if(*payload == 49){
...
}

You should check that the topic is the actual topic you are interested in and that the length is also what you expect, before you start looking at the payload.