Dynamically add a property or method to an object in groovy

Question

Is it possible to add a property or a method to an object dynamically in Groovy? This is what I have tried so far:

class Greet {
  def name
  Greet(who) { name = who[0].toUpperCase() + [1..-1] }
  def salute() { println "Hello $name!" }
}

g = new Greet('world')  // create object
g.salute()              // Output "Hello World!"

g.bye = { println "Goodbye, $name" }
g.bye()

But I get the following exception:

Hello World!
Caught: groovy.lang.MissingPropertyException: No such property: bye for class: Greet
Possible solutions: name
    at test.run(greet.groovy:11)

Answer 1

If you just want to add the bye() method to the single instance g of the class Greet, you need to do:

g.metaClass.bye = { println "Goodbye, $name" }
g.bye()

Otherwise, to add bye() to all instance of Greet (from now on), call

Greet.metaClass.bye = { println "Goodbye, $name" }

But you'd need to do this before you create an instance of the Greet class

Here is a page on the per-instance metaClass

And here is the page on MetaClasses in general

---

Also, there's a bug in your constructor. You're missing who from infront of your [1..-1] and if the constructor is passed a String of less than 2 characters in length, it will throw an exception

A better version might be:

Greet( String who ) { 
  name = who.inject( '' ) { String s, String c ->
    s += s ? c.toLowerCase() : c.toUpperCase()
  }
}

---

As metioned in the comments,

Greet( String who ) { 
  name = who.capitalize()
}

is the proper way