how can i get list of book from Wikibooks with SPARQL query

Question

how can i get list of book from Wikibooks with SPARQL query fo example : PREFIX dbo:http://dbpedia.org/ontology/ PREFIX dba:http://dbpedia.org/ontology/
SELECT ?author ?name ?label ?text ?title ?isbn ?publisher ?literaryGenre ?pages WHERE
{?book a dbo:Book.
?book dbo:author ?author. ?book dbo:numberOfPages ?pages. ?book dbp:title ?title. ?book dba:isbn ?isbn. ?book dba:publisher ?publisher.

FILTER regex(?title , "java") . }

Answer 1

I'm wondering whether you know that Wikibooks is not Wikipedia and DBpedia is based on Wikipedia?!

And then, why do you have two prefixes dbo and dba for the same namespace http://dbpedia.org/ontology/ ? I really suggest to understand what you're doing and what the query does instead of copy and paste from some other sources. SPARQL and RDF tutorials might help, and also the official documentation is useful.

Next issue, you SELECT variables ?name, ?label, ?text and ?literaryGenre which are not bound in a triple pattern in the WHERE part. It's also not clear what you expect to get for ?text. The whole text of the book?! For sure, this won't exist, think about copyrights. And what would be the difference between ?name and ?title? I don't think that dbp:title is the appropriate property here, see

PREFIX dbo: <http://dbpedia.org/ontology/> 
PREFIX dbp: <http://dbpedia.org/property/>

SELECT count(*) WHERE {
?book a dbo:Book ;
      dbp:title ?title. 
}

which returns 19 only.

My suggestion:

PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#> 

SELECT * WHERE {
 ?book a dbo:Book .
 ?book dbo:author ?author . 
 OPTIONAL { ?book dbo:numberOfPages ?pages }
 OPTIONAL { ?book dbo:isbn ?isbn }
 OPTIONAL { ?book dbo:publisher ?publisher }

 # get the English title
 ?book rdfs:label ?name.
 FILTER(LANGMATCHES(LANG(?name), 'en'))

 # get an English description, but not the text
 ?book rdfs:comment ?text .
 FILTER(LANGMATCHES(LANG(?text), 'en'))

 # filter for books whose title contains "java"
 FILTER regex(str(?name) , "java", "i") . 
}

More efficient using the Virtuoso fulltext index predicate bif:contains:

PREFIX dbo: <http://dbpedia.org/ontology/> 
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT * WHERE {
 ?book a dbo:Book .
 ?book dbo:author ?author . 
 OPTIONAL { ?book dbo:numberOfPages ?pages }
 OPTIONAL { ?book dbo:isbn ?isbn }
 OPTIONAL { ?book dbo:publisher ?publisher }

 # get the English title
 ?book rdfs:label ?name.
 FILTER(LANGMATCHES(LANG(?name), 'en'))

 # get an English description, but not the text
 ?book rdfs:comment ?text .
 FILTER(LANGMATCHES(LANG(?text), 'en'))


 # filter for books whose title contains "java"
 ?name bif:contains '"java"'
}

As a book might have multiple authors resp. publisher you might get duplicate rows, here GROUP_BY in combination with GROUP_CONCAT is the way to go (grouped by book):

PREFIX dbo: <http://dbpedia.org/ontology/> 
PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?book (group_concat(DISTINCT ?author; separator = ", ") as ?authors) (group_concat(DISTINCT ?publisher; separator = ", ") as ?publishers) (sample(?pages) as ?numPages) (sample(?isbn_tmp) as ?isbn) WHERE {
?book a dbo:Book .
?book dbo:author ?author . 
OPTIONAL { ?book dbo:numberOfPages ?pages }
OPTIONAL { ?book dbo:isbn ?isbn_tmp }
OPTIONAL { ?book dbo:publisher ?publisher }

# get the English title
?book rdfs:label ?name.
FILTER(LANGMATCHES(LANG(?name), 'en'))

# get an English description, but not the text
?book rdfs:comment ?text .
FILTER(LANGMATCHES(LANG(?text), 'en'))


# filter for books whose title contains "java"
?name bif:contains '"java"'
}
GROUP BY ?book