Keypad on arduino

Question

I'm working on a project on which I'm using a keypad to type a password, what I've done is that I'm reading keys typed by the user and collect it in an array to compare it with the password. The problem that I'm facing is that when I compare the typed word and and the correct password I'm getting always "wrong password".

Here is my code:

#include "Keypad.h"
const byte ROWS = 4; //four rows
const byte COLS = 3; //three columns
char keys[ROWS][COLS] = {
{'1','2','3'},
{'4','5','6'},
{'7','8','9'},
{'*','0','#'}
};
char passwrd[7];
char cst[7]="*1998#";
 byte rowPins[ROWS] = {28, 27, 26, 25}; //connect to the row pinouts of the   keypad
 byte colPins[COLS] = {24, 23, 22}; //connect to the column pinouts of the keypad

 Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, ROWS, COLS);

 void setup()
{
    Serial.begin(9600);
}

void loop()
{

   int i=0;
 do
 {
     char key = keypad.getKey();
     if (key != NO_KEY)
     {
        passwrd[i]=key;
        i++;
        Serial.println(key);
     }
 }while (i!=6);
 Serial.println(passwrd);
 Serial.println(cst);
 if (passwrd==cst)
 {
     Serial.println("correct passwrd");
 }
 else 
 {
     Serial.println("wrong passwrd");
 }
}

Here is what I'm getting from the serial com:

*
1
9
9
8
#
*1998#
*1998#
wrong passwrd

Where is the problem?

Answer 1

Using == on a char* will compare the address that the pointer points to in memory, since a c-type string is a pointer. You need to use the strcmp() function.

strcmp() returns 0 if the c-strings are identical.

This should work:

if (strcmp(passwrd, cst) == 0)
{
    Serial.println("correct passwrd");
}
else 
{
    Serial.println("wrong passwrd");
}

Demonstration

Put this on your Arduino to demonstrate this:

void setup() {
  // put your setup code here, to run once:
  Serial.begin(115200);
}

char* are_the_same(int val) {
  if(val == 0)
    return "No";
  return "Yes";
}

void loop() {
  // put your main code here, to run repeatedly:
  char* one = "test";
  char two[5];

  // We are copying 'test' into string two. If we don't do this the compiler will optimise and make them point to the same piece of memory and ruin the demonstration.
  int i;
  for (i = 0; i < 5; i++)
    two[i] = one[i];

  Serial.print("one == two, are they the same? ");
  Serial.println(are_the_same(one == two));

  Serial.print("strcmp(one, two) == 0, are they the same? ");
  Serial.println(are_the_same(strcmp(one, two) == 0));
  Serial.println();
  delay(1000);
}

This will give you:

one == two, are they the same? No
strcmp(one, two) == 0, are they the same? Yes