Perl6 grammar and action error : "Cannot find method 'ann' on object of type NQPMu"

Question

I am still having trouble with Perl6 grammar and action. I want to find a pattern in a string, and as soon as it is is found, change the pattern according to action, and return the modified string.

my $test = "xx, 1-March-23, 23.feb.21, yy foo  12/january/2099 , zzz";
# want this result: xx, 010323, 230221, yy foo  120199 , zzz"; 
# 2 digits for day, month, year

grammar month {
    regex TOP { <unit>+ }
    regex unit { <before> <form1> <after> }
    regex before { .*? }
    regex after  { .*? }
    regex form1 { \s* <dd> <slash> <mon> <slash> <yy> \s* }
    regex slash { \s* <[ \- \/ \. ]> \s* }
    regex dd    { \d ** 1..2 }
    regex yy    { (19 | 20)? \d\d }
    proto regex mon {*}
    regex mon:sym<jan> { \w 'an' \w* }
    regex mon:sym<feb> { <sym> }
    regex mon:sym<mar> { <[Mm]> 'ar' \w* }
}
class monAct {
    method TOP ($/) { make $<unit>.map({.made}); }
    method unit  ($/) { make $<before> ~ $<form1>.made ~$<after>; }
    method form1 ($/) { make $<dd>.made ~ $<mon>.made ~ $<yy>; }
    method dd ($/) {
        my $ddStr = $/.Str;
        if $ddStr.chars == 1 { make "0" ~ $ddStr; } else { make $ddStr; }
    }
    method mon:sym<jan> ($/) { make "01"; };
    method mon:sym<feb> ($/) { make "02"; };
    method mon:sym<mar> ($/) { make "03"; };
}

my $m = month.parse($test, actions => monAct.new);
say $m;
say $m.made;

But it says:

===SORRY!===Cannot find method 'ann' on object of type NQPMu

What did I do wrong?

Answer 1

This looks like a bug in Rakudo to me, possibly related to before being part of the syntax for lookahead assertions.

It can already be triggered with a simple / <before> /:

$ perl6 --version
This is Rakudo version 2016.11-20-gbd42363 built on MoarVM version 2016.11-10-g0132729
implementing Perl 6.c.

$ perl6 -e '/ <before> /'
===SORRY!===
Cannot find method 'ann' on object of type NQPMu

At the very least, it's a case of a less than awesome error message.

You should report this to [email protected], cf How to report a bug.