AutoHotkey - Rename image by desired name only by selecting it and pressing shortcut

Question

I have a quite organized workflow and I have an image that always needs to have the same name. It's always a PNG (Portable Network Graphics) and no matter if it's on Desktop or in a folder.

So i just want to select the image and with a one letter shortcut (for example "L") rename it (regardless it's previous name) to "LAYOUT"

Answer 1

F2::
ClipSaved := ClipboardAll       ; save the entire clipboard to the variable ClipSaved
clipboard := ""                 ; empty clipboard
Send, ^c                        ; copy the selected file
ClipWait, 1                     ; wait for the clipboard to contain data
if (!ErrorLevel)                ; If NOT ErrorLevel clipwait found data on the clipboard
{
    clipboard := clipboard      ; convert to text (= copy the path of the selected file)
    Sleep, 300 
    ; MsgBox, %clipboard%       ; display the path
    if (SubStr(clipboard, -2) != "png")
    {
        MsgBox, No PNG-file selected
        clipboard := ClipSaved
            return
    }
    ; otherwise:
    SplitPath, clipboard, name, dir
    FileMove, %clipboard%, %dir%\LAYOUT.png
    Sleep, 100
    clipboard := ClipSaved       ; restore original clipboard
}
else
{
    MsgBox, No file selected
    clipboard := ClipSaved 
}
return