Removing extra parentheses in Scheme

Question

Using a Scheme-like language, I am converting

(quote (lambda (a b) (* a b) (+ a b))))

to:

(quote (lambda (a) (lambda (b) (+ a b) (* a b))))

but with my current implementation I am getting an extra pair of parenthesis around the expressions (+ a b) and (* a b):

(lambda (a) (lambda (b) ((+ a b) (* a b))))

I have spent a lot of time trying to fix this problem, but can't figure it out. I feel like the fix should be trivial.

Here is my code currently:

(define (conv lyst)

  (define (helper args)
    (cond
      ((null? args) (append (cddr lyst) args))
      (else (cons (car lyst) 
                  (cons (list (car args)) 
                        (list (helper (cdr args))))))))

  (cond
    ((eq? 1 (length (car (cdr lyst)))) lyst)
    (else (helper (car (cdr lyst))))))

Answer 1

I think your implementation can be simplified. This should work:

(define (conv lyst)  
  (define (helper args)
    (if (null? (cdr args))
        (cons 'lambda
              (append (list (list (car args)))
                      (cddr lyst)))
        (list  'lambda
               (list (car args))
               (helper (cdr args)))))
  (helper (cadr lyst)))

Or even simpler, using quasiquoting and splicing:

(define (conv lyst)  
  (define (helper args)
    (if (null? (cdr args))
        `(lambda (,(car args)) ,@(cddr lyst))
        `(lambda (,(car args)) ,(helper (cdr args)))))
  (helper (cadr lyst)))

Either way, it works as expected:

(conv '(lambda (a b) (* a b) (+ a b)))
=> '(lambda (a) (lambda (b) (* a b) (+ a b)))