WebFocus, two title columns and merging cells

Question

If i have a table in a WebFocus Raport design

+--------+---------+--------+---------+
| left_1 | right_1 | left_2 | right_2 |
+--------+---------+--------+---------+
| v11    | p11     | v21    | v21     |
+--------+---------+--------+---------+
| v12    | p12     | v22    | v22     |
....

How to do a such table with syllabus column titles:

+-------+-------+-------+-------+
|     One       |     Two       |
+-------+-------+-------+-------+
| left  | right | left  | right |
+-------+-------+-------+-------+
| v11   | p11   | v21   | v21   |
+-------+-------+-------+-------+
| v12   | p12   | v22   | v22   |
....

Thank you

Answer 1

Sorry for the delay of the answer :)

To rename columns, with the AS command. Example:

TABLE FILE SYSTABLE
PRINT NAME
COMPUTE LEFT1/A3  = 'v11'; AS 'left';
COMPUTE RIGHT1/A3 = 'p11'; AS 'right';
COMPUTE LEFT2/A3  = 'v21'; AS 'left';
COMPUTE RIGHT2/A3 = 'p21'; AS 'right';
IF RECORDLIMIT EQ 10
END

To put the heading columns, you can work with the ACROSS command but it will be more tricky that if u use simply SUBHEAD. With the same example:

TABLE FILE SYSTABLE
PRINT NAME NOPRINT
COMPUTE LEFT1/A3  = 'v11'; AS 'left';
COMPUTE RIGHT1/A3 = 'p11'; AS 'right';
COMPUTE LEFT2/A3  = 'v21'; AS 'left';
COMPUTE RIGHT2/A3 = 'p21'; AS 'right';
IF RECORDLIMIT EQ 10
ON TABLE SUBHEAD
"<+0>One<+0> Two"
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
           UNITS=IN, PAGESIZE='Letter',
           LEFTMARGIN=0.500000,  RIGHTMARGIN=0.500000,
           TOPMARGIN=0.500000,   BOTTOMMARGIN=0.500000,
           SQUEEZE=ON, GRID=OFF, ORIENTATION=LANDSCAPE, $
TYPE=REPORT,FONT='ARIAL',SIZE=9,$
TYPE=TABHEADING,HEADALIGN=BODY,$
TYPE=TABHEADING, LINE=1, ITEM=1, COLSPAN=2, SQUEEZE=ON,$
TYPE=TABHEADING, LINE=1, ITEM=2, COLSPAN=2, SQUEEZE=ON,$
ENDSTYLE
END

Hope it helps!