Intersystems caché - sql storage definition

Question

How to set Name property of %Dictionary.StorageSQLMapDefinition class? I have this code:

set storMaps = ##class(%Dictionary.StorageSQLMapDefinition).%New()
set storMaps.Name = ?????

And i don´t know how to set storMaps.Name. Data type of Name prop. is %Dictionary.SQLIdentifier according to documentation. But i don´t know how to set this property. I get an error:

SQL Map type is invalid

Answer 1

You maybe forgot about %Dictionary.StorageDefintion.

    set clsDef=##class(%Dictionary.ClassDefinition).%OpenId("User.Test")

    set storage=##class(%Dictionary.StorageDefinition).%New()
    set storage.Name="Test"
    set storage.Type="%CacheSQLStorage" // this is important

    set storageMap=##class(%Dictionary.StorageSQLMapDefinition).%New()
    set storageMap.Name="MasterMap"
    set storageMap.Global="^global"
    do storage.SQLMaps.Insert(storageMap)

    set data=##class(%Dictionary.StorageSQLMapDataDefinition).%New()
    set data.Name="name"
    set data.Node=1
    do storageMap.Data.Insert(data)

    set data=##class(%Dictionary.StorageSQLMapDataDefinition).%New()
    set data.Name="type"
    set data.Node=2
    do storageMap.Data.Insert(data)

    set subscript=##class(%Dictionary.StorageSQLMapSubDefinition).%New()
    set subscript.Name=1
    set subscript.Expression="""test"""
    do storageMap.Subscripts.Insert(subscript)

    set subscript=##class(%Dictionary.StorageSQLMapSubDefinition).%New()
    set subscript.Name=2
    set subscript.Expression="{ID}"
    do storageMap.Subscripts.Insert(subscript)

    set rowidspec=##class(%Dictionary.StorageSQLMapRowIdSpecDefinition).%New()
    set rowidspec.Name=1
    set rowidspec.Expression="{L2}"
    set rowidspec.Field="ID"
    do storageMap.RowIdSpecs.Insert(rowidspec)

    do clsDef.Storages.Insert(storage)
    set tSC=clsDef.%Save()

code above will create storage like this

<Storage name="Test">
<SQLMap name="MasterMap">
<Data name="name">
<Node>1</Node>
</Data>
<Data name="type">
<Node>2</Node>
</Data>
<Global>^global</Global>
<RowIdSpec name="1">
<Expression>{L2}</Expression>
<Field>ID</Field>
</RowIdSpec>
<Subscript name="1">
<Expression>"test"</Expression>
</Subscript>
<Subscript name="2">
<Expression>{ID}</Expression>
</Subscript>
</SQLMap>
<Type>%CacheSQLStorage</Type>
</Storage>