Delphi XE LiveBindings - Bits to Byte

Question

I just discovered livebindings with Delphi. And created my first components for handling a control-word for a frequency converter. The component it self seems to work well testing it in the form designer. However, compiling and running the application things doesn't work. Screenshot from livbindings like this:

And here is the code for the component

unit cBits2Byte;

interface

uses
  System.SysUtils, System.Classes;

type
  TBits2Byte = class(TComponent)
  private
    { Private declarations }
    fBit00, fBit01, fBit02, fBit03, fBit04, fBit05, fBit06, fBit07: Boolean;
    function bitstate(sfr, bit: Byte): Boolean;
    function ReadByte: Byte;
    procedure WriteByte(aByte: Byte);
  published
    { Published declarations }
    property char: byte read ReadByte write WriteByte;

    property Bit00: Boolean read fBit00 write fBit00;
    property Bit01: Boolean read fBit01 write fBit01;
    property Bit02: Boolean read fBit02 write fBit02;
    property Bit03: Boolean read fBit03 write fBit03;
    property Bit04: Boolean read fBit04 write fBit04;
    property Bit05: boolean read fBit05 write fBit05;
    property Bit06: boolean read fBit06 write fBit06;
    property Bit07: boolean read fBit07 write fBit07;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Standard', [TBits2Byte]);
end;

function TBits2Byte.bitstate(sfr, bit: Byte): Boolean;
begin
  Result := Boolean( (sfr shr bit) And $01);
end;

function TBits2Byte.ReadByte: Byte;
begin
  Result := (Ord(Bit07) shl 7) Or
            (Ord(Bit06) shl 6) Or
            (Ord(Bit05) shl 5) Or
            (Ord(Bit04) shl 4) Or
            (Ord(Bit03) shl 3) Or
            (Ord(Bit02) shl 2) Or
            (Ord(Bit01) shl 1) Or
            (Ord(Bit00));
end;

procedure TBits2Byte.WriteByte(aByte: Byte);
begin
  Bit00 := bitstate(aByte, 0);
  Bit01 := bitstate(aByte, 1);
  Bit02 := bitstate(aByte, 2);
  Bit03 := bitstate(aByte, 3);
  Bit04 := bitstate(aByte, 4);
  Bit05 := bitstate(aByte, 5);
  Bit06 := bitstate(aByte, 6);
  Bit07 := bitstate(aByte, 7);
end;

end.

So, what am I lacking to have this work as a livebinding?

Answer 1

You have to use a BindSource for the binding. In this example I just use the TPrototypeBindSource.

There is no need to have an component for the data object, a simple object is enough.

unit DataObject;

interface

type
  TBits2Byte = class
  private
    { Private declarations }
    fBit00, fBit01, fBit02, fBit03, fBit04, fBit05, fBit06, fBit07: Boolean;
    function bitstate( sfr, bit: Byte ): Boolean;
    function ReadByte: Byte;
    procedure WriteByte( aByte: Byte );
  published
    { Published declarations }
    property char: Byte read ReadByte write WriteByte;

    property Bit00: Boolean read fBit00 write fBit00;
    property Bit01: Boolean read fBit01 write fBit01;
    property Bit02: Boolean read fBit02 write fBit02;
    property Bit03: Boolean read fBit03 write fBit03;
    property Bit04: Boolean read fBit04 write fBit04;
    property Bit05: Boolean read fBit05 write fBit05;
    property Bit06: Boolean read fBit06 write fBit06;
    property Bit07: Boolean read fBit07 write fBit07;
  end;

implementation

function TBits2Byte.bitstate( sfr, bit: Byte ): Boolean;
begin
  Result := Boolean( ( sfr shr bit ) And $01 );
end;

function TBits2Byte.ReadByte: Byte;
begin
  Result :=
  {} ( Ord( Bit07 ) shl 7 ) Or
  {} ( Ord( Bit06 ) shl 6 ) Or
  {} ( Ord( Bit05 ) shl 5 ) Or
  {} ( Ord( Bit04 ) shl 4 ) Or
  {} ( Ord( Bit03 ) shl 3 ) Or
  {} ( Ord( Bit02 ) shl 2 ) Or
  {} ( Ord( Bit01 ) shl 1 ) Or
  {} ( Ord( Bit00 ) shl 0 );
end;

procedure TBits2Byte.WriteByte( aByte: Byte );
begin
  Bit00 := bitstate( aByte, 0 );
  Bit01 := bitstate( aByte, 1 );
  Bit02 := bitstate( aByte, 2 );
  Bit03 := bitstate( aByte, 3 );
  Bit04 := bitstate( aByte, 4 );
  Bit05 := bitstate( aByte, 5 );
  Bit06 := bitstate( aByte, 6 );
  Bit07 := bitstate( aByte, 7 );
end;

end.

Now the form with the binding

unit Form.Main;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Data.Bind.Components,
  Data.Bind.ObjectScope, System.Rtti, System.Bindings.Outputs, Vcl.Bind.Editors,
  Data.Bind.EngExt, Vcl.Bind.DBEngExt, Vcl.StdCtrls;

type
  TForm1 = class( TForm )
    Bits2ByteSource: TPrototypeBindSource; 
      { OnCreateAdapter -> Bits2ByteSourceCreateAdapter }
    CheckBox1: TCheckBox;
    CheckBox2: TCheckBox;
    CheckBox3: TCheckBox;
    CheckBox4: TCheckBox;
    CheckBox5: TCheckBox;
    CheckBox6: TCheckBox;
    CheckBox7: TCheckBox;
    CheckBox8: TCheckBox;
    Edit1: TEdit;    
    procedure Bits2ByteSourceCreateAdapter( Sender: TObject; var ABindSourceAdapter: TBindSourceAdapter );
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

uses
  DataObject;

{$R *.dfm}

procedure TForm1.Bits2ByteSourceCreateAdapter( Sender: TObject; var ABindSourceAdapter: TBindSourceAdapter );
begin

  // create the adapter and an instance of the data object

  ABindSourceAdapter := TObjectBindSourceAdapter<TBits2Byte>.Create(
    {AOwner} Self,
    {AObject} TBits2Byte.Create,
    {AOwnsObject} True );

  ABindSourceAdapter.AutoEdit := True;
  ABindSourceAdapter.AutoPost := True;
end;

end.

The rest is done with the livebindings.

Declare all fields in the TPrototypeBindSource I named Bits2ByteSource with the field editor:

Bit00 -> ftBoolean
Bit01 -> ftBoolean
Bit02 -> ftBoolean
Bit03 -> ftBoolean
Bit04 -> ftBoolean
Bit05 -> ftBoolean
Bit06 -> ftBoolean
Bit07 -> ftBoolean
Char -> ftChar

and after that bind all the fields with the controls

Ready for take off.

---

Just to mention:

The TEdit.Text value is only updated after leaving the control. If you want to have that field changed immediately then you have to set the (VCL) TEdit.OnChange / (FMX) TEdit.OnChangeTracking event with

TLinkObservers.ControlChanged( Edit1 );

or you will have a general method for this

procedure TForm1.ControlChanged( Sender : TObject );
begin
  if Sender is TComponent then
    TLinkObservers.ControlChanged( Sender as TComponent );
end;