Change node name and wrapping nodes

Question

I just began to work on XSLT. My input and expected output are as follows and the XSLT is also given below.

I have next input XML:

<servicio>
   <control>
         <codSer>00013</codSer>
         <idMen>12378658936578</idMen>
         <codErr>000</codErr>
         <numId>000xxxxxxxx</numId>
   </control>
   <cuentas>
         <tipPro>3</tipPro>
         <numCta>000000006</numCta>
         <tipCta>A</tipCta>
         <desCta>Cuenta I</desCta>
         <saldo>001513003135</saldo>
   </cuentas>
   <cuentas>
         <tipPro>1</tipPro>
         <numCta>000000005</numCta>
         <tipCta>A</tipCta>
         <desCta>Cuenta I</desCta>
         <saldo>007573144537</saldo>
         <signo>Pos</signo>
   </cuentas>
   <fondos>
         <tipPro>4</tipPro>
         <numCta>000000007</numCta>
         <tipCta>A</tipCta>
         <desCta>Fondo I</desCta>
         <saldo>001513003135</saldo>
   </fondos>
   <fondos>
         <tipPro>4</tipPro>
         <numCta>000000008</numCta>
         <tipCta>A</tipCta>
         <desCta>Fondo I</desCta>
         <saldo>007573144537</saldo>
   </fondos>
</servicio>

And I need apply an XSL to get (output):

<servicio>
<control>
    <codSer>00013</codSer>
    <idMen>12378658936578</idMen>
    <codErr>000</codErr>
    <numId>000xxxxxxxx</numId>
</control>
<cuentas>
    <cuenta>
        <tipPro>3</tipPro>
        <numCta>000000006</numCta>
        <tipCta>A</tipCta>
        <desCta>Cuenta I</desCta>
        <saldo>001513003135</saldo>
    </cuenta>
    <cuenta>
        <tipPro>1</tipPro>
        <numCta>000000005</numCta>
        <tipCta>A</tipCta>
        <desCta>Cuenta I</desCta>
        <saldo>007573144537</saldo>
        <signo>Pos</signo>
    </cuenta>
</cuentas>
<fondos>
    <fondo>
        <tipPro>4</tipPro>
        <numCta>000000007</numCta>
        <tipCta>A</tipCta>
        <desCta>Fondo I</desCta>
        <saldo>001513003135</saldo>
    </fondo>
    <fondo>
        <tipPro>4</tipPro>
        <numCta>000000008</numCta>
        <tipCta>A</tipCta>
        <desCta>Fondo I</desCta>
        <saldo>007573144537</saldo>
    </fondo>
</fondos>
</servicio>

the XSL I tried and didn't work is:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="2.0">
<xsl:output method="xml" />
<xsl:strip-space elements="*" />
<xsl:output indent="yes" />
<xsl:param name="elementInfo" select="cuentas,cuentas,cuenta;fondos,fondos,fondo"/>

<xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*" />
    </xsl:copy>
</xsl:template>

<xsl:template match="node()[name() = name(/*)]">
    <xsl:variable name="inputNode" select="." />
    <xsl:for-each select="tokenize($elementInfo, ';')">
        <xsl:variable name="tokenizedNodeNames" select="tokenize(.,',')" />
        <xsl:for-each select="$inputNode">
            <xsl:call-template name="wrapping">
                <xsl:with-param name="wrapperElementName" select="$tokenizedNodeNames[1]" />
                <xsl:with-param name="oldElementName" select="$tokenizedNodeNames[2]" />
                <xsl:with-param name="newElementName" select="$tokenizedNodeNames[3]" />
            </xsl:call-template>
        </xsl:for-each>
    </xsl:for-each>
</xsl:template>

<xsl:template name="wrapping">
    <xsl:param name="wrapperElementName" />
    <xsl:param name="oldElementName" />
    <xsl:param name="newElementName" />
    <xsl:copy>
        <xsl:apply-templates select="node()[not(name() = $oldElementName)]" />
        <xsl:element name="{$wrapperElementName}">
            <xsl:for-each select="node()[name() = $oldElementName]">
                <xsl:element name="{$newElementName}">
                    <xsl:copy-of select="@*|node()" />
                </xsl:element>
            </xsl:for-each>
        </xsl:element>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

When I have an input XML whit only CUENTAS it works but when I tried whit FONDOS I was geting mal format XML.

Answer 1

I think you simply want to group elements like cuentas and fondos by their node-name():

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema" 
  exclude-result-prefixes="#all"
  version="2.0">

<xsl:strip-space elements="*"/>
<xsl:output indent="yes"/>

<xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* , node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="/*">
  <xsl:copy>
    <xsl:for-each-group select="*" group-by="node-name(.)">
      <xsl:apply-templates select="." mode="wrap"/>
    </xsl:for-each-group>
  </xsl:copy>
</xsl:template>

<xsl:template match="*" mode="wrap">
  <xsl:apply-templates select="current-group()"/>
</xsl:template>

<xsl:template match="cuentas | fondos" mode="wrap">
  <xsl:copy>
    <xsl:apply-templates select="current-group()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="cuentas | fondos">
  <xsl:element name="{substring(local-name(), 1, string-length(local-name()) - 1)}">
    <xsl:apply-templates select="@* | node()"/>
  </xsl:element>
</xsl:template>

</xsl:stylesheet>

That way, with Saxon 9.5, I get the result

<servicio>
   <control>
      <codSer>00013</codSer>
      <idMen>12378658936578</idMen>
      <codErr>000</codErr>
      <numId>000xxxxxxxx</numId>
   </control>
   <cuentas>
      <cuenta>
         <tipPro>3</tipPro>
         <numCta>000000006</numCta>
         <tipCta>A</tipCta>
         <desCta>Cuenta I</desCta>
         <saldo>001513003135</saldo>
      </cuenta>
      <cuenta>
         <tipPro>1</tipPro>
         <numCta>000000005</numCta>
         <tipCta>A</tipCta>
         <desCta>Cuenta I</desCta>
         <saldo>007573144537</saldo>
         <signo>Pos</signo>
      </cuenta>
   </cuentas>
   <fondos>
      <fondo>
         <tipPro>4</tipPro>
         <numCta>000000007</numCta>
         <tipCta>A</tipCta>
         <desCta>Fondo I</desCta>
         <saldo>001513003135</saldo>
      </fondo>
      <fondo>
         <tipPro>4</tipPro>
         <numCta>000000008</numCta>
         <tipCta>A</tipCta>
         <desCta>Fondo I</desCta>
         <saldo>007573144537</saldo>
      </fondo>
   </fondos>
</servicio>