Add empty line between task groups?

Question

I have an installer script like this:

[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName={pf}\My Program

[Tasks]
Name: group1; Description: "Check/uncheck all"; GroupDescription: "1. Group description"; Flags: unchecked
Name: group1\task1; Description: "1. Task"; Flags: unchecked
Name: group1\task2; Description: "2. Task"; Flags: unchecked

; Here should be visible an empty line in the UI Tasks page to separate groups

Name: group2; Description: "Check/uncheck all"; GroupDescription: "2. Group description"; Flags: unchecked
Name: group2\task1; Description: "1. Task"; Flags: unchecked
Name: group2\task2; Description: "2. Task"; Flags: unchecked

I wonder if I could add an empty element between the tasks groups, just to make a kind of "empty line" effect in the resulting UI, I mean to add a little blank space in the tasks page between group1 of tasks and group 2.

How I could do this?

Answer 1

The only way I could come up is adding a line break before the group description. That's what can be done e.g. like this:

[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName={pf}\My Program

[CustomMessages]
; %n here is a line break, so here we are inserting a line break before the text
TaskGroup2Descr=%n2. Group description

[Tasks]
Name: group1; Description: "Check/uncheck all"; GroupDescription: "1. Group description"; Flags: unchecked
Name: group1\task1; Description: "1. Task"; Flags: unchecked
Name: group1\task2; Description: "2. Task"; Flags: unchecked

Name: group2; Description: "Check/uncheck all"; GroupDescription: "{cm:TaskGroup2Descr}"; Flags: unchecked
Name: group2\task1; Description: "1. Task"; Flags: unchecked
Name: group2\task2; Description: "2. Task"; Flags: unchecked