Plot received powers with gnuplot

I'd like to plot the received powers over different wireless channels. For each channel, I have three values, and I want to plot them stacked.

Actually, this is my script:

set boxwidth 0.6 relative
set ylabel "dBm"
set xlabel "Channel"
set style fill solid
set key off
plot "RR1" using 1:2 with boxes, "RR2" using 1:2 with boxes, "RR3" using 1:2 with boxes

The problem is that since they are negative values (dBm), it plots from 0 to the value it finds, and thus the highest power is on the top. I'd like to plot a somewhat reverse image, with the blue box starting from the bottom up to the value it reaches, and the same for the other two values.

enter image description here

Any idea?

My data looks like this

21.0 -93.9207
22.0 -92.241
23.0 -93.452

Solution

One possibity is to use the boxxyerrorbars plotting style:

reset
set ylabel "dBm"
set xlabel "Channel"
set style fill solid
set key off
set style data boxxyerrorbars

set xtics 1
set autoscale xfix
set offset 0.5,0.5,0,0

ylow = -100
plot for [i=3:1:-1] sprintf("RR%d", i) using 1:(0.5*($2+ylow)):(0.3):(0.5*($2-ylow)) lt i

Here, I used a fixed lower y-value, but you could also extract it from the data file with stats and do some other tweaking.

In the using statement, the second column gives the box center, which is the mean of actual y-value and the lower boundary, the third column is x-delta (half of the actual box width), and the fourth column is y-delta.

With some more data values, this gives:

enter image description here