Batch Renaming Folders in AppleScript, Will Only Change Names of Every Other Folder

Question

I am trying to write a script that renames folders in subfolders. In other words, the taxonomy will go from:

Directory/Company X/1
Directory/Company X/2
Directory/Company X/3
Directory/Company X/4
Directory/Company X/5
Directory/Company X/6
Directory/Company X/7
Directory/Company X/8
Directory/Company X/9
Directory/Company X/10
Directory/Company X/info

to

Directory/Company X/Project 1_1
Directory/Company X/Project 2_2
Directory/Company X/Project 3_3
etc..

So far I have:

tell application "Finder"

-- Defining Pro Folders 
set pro_folder to folder POSIX file "/Users/Jart/Desktop/test"
set all_pro_folders to every folder of pro_folder

-- Iterate through folders and check if folder name is greater than one character
repeat with x in all_pro_folders
    repeat with y in x
        -- Convert the folder name to a string and check if that string is longer than one character
        set incomingName to folder ((y as alias) as text)
        set incomingNameString to name of incomingName
        if length of incomingNameString = 1 then
            -- Set old name (number) to a new variable
            set oldname to folder ((y as alias) as text)
            set oldnameString to name of oldname
            -- Do it again for the second part
            set oldname2 to folder ((y as alias) as text)
            set oldnameString2 to name of oldname2
            -- Rename here
            set name of y to "Project" & " " & oldnameString & "_" & oldnameString
        end if
    end repeat
end repeat

end tell

However, the folder now looks like:

Directory/Company X/3
Directory/Company X/5
Directory/Company X/7
Directory/Company X/9
Directory/Company X/10
Directory/Company X/info
Directory/Company X/Project 1_1
Directory/Company X/Project 2_2
Directory/Company X/Project 4_4
Directory/Company X/Project 6_6
Directory/Company X/Project 8_8

Why is it doing this? How do I change this code so it will rename all the files? If you want, I can dump the Events/Replies log.

Answer 1

Jart, the main issue was with the second loop, you need to be looping through every folder of the x folder variable instead. It appears that looping through the folder worked, but when you renamed them it caused an index issue resulting in only reading every 2nd folder.

Here is a little reworking.

• renamed your variables from y and x to be less cryptic.
• changed the length test to support names > 9.
• i was unsure about the item at the end of the new name, and if it should be an incremented number instead. (you can easily revert)
• left in some log calls for your reference, these can help debug stuff

tell application "Finder"
    -- Defining Pro Folders 
    set pro_folder to folder POSIX file "/Users/Jart/Desktop/test"
    set all_pro_folders to every folder of pro_folder

    -- Iterate through folders and check if folder name is greater than one character
    repeat with parent_folder in all_pro_folders
        set counter to 0 -- reset a counter variable we use for the end of the name 
        set child_folders to every folder of parent_folder
        repeat with current_folder in child_folders
            set fold_name to the name of current_folder
            log (fold_name)
            if (the length of fold_name < 3) then -- this will allow names > 9  
                set counter to counter + 1 -- increment the counter every time we find valid folder
                set new_name to "Project" & " " & fold_name & "_" & counter
                log (new_name)
                set the name of current_folder to new_name
            end if
        end repeat
    end repeat
end tell

HTH