I'm using this JEDI component to enumerate files but I can't get it skip over junctions. Is there a setting or modification to the code I can do to fix this?
I am not 100% sure of the relevant code in the jvsearchfiles.pas unit. But I think it is is here:
function TJvSearchFiles.EnumFiles(const ADirectoryName: string;
Dirs: TStrings; const Search: Boolean): Boolean;
var
Handle: THandle;
Finished: Boolean;
DirOK: Boolean;
begin
DoBeginScanDir(ADirectoryName);
{ Always scan the full directory - ie use * as mask - this seems faster
then first using a mask, and then scanning the directory for subdirs }
Handle := FindFirstFile(PChar(ADirectoryName + '*'), FFindData);
Result := Handle <> INVALID_HANDLE_VALUE;
if not Result then
begin
Result := GetLastError in [ERROR_FILE_NOT_FOUND, ERROR_ACCESS_DENIED];;
Exit;
end;
Finished := False;
try
while not Finished do
begin
// (p3) no need to bring in the Forms unit for this:
if not IsConsole then
DoProgress;
{ After DoProgress, the user can have called Abort,
so check it }
if FAborting then
begin
Result := False;
Exit;
end;
with FFindData do
{ Is it a directory? }
if (dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY > 0) then
begin
{ Filter out '.' and '..'
Other dir names can't begin with a '.' }
{ | Event | AddDir | SearchInDir
-----------------------------------------------------------------
doExcludeSubDirs |
True | Y N N
False | N N N
doIncludeSubDirs |
True | Y Y Y
False | N Y Y
doExcludeInvalidDirs |
True | Y Y Y
False | N Y N
doExcludeCompleteInvalidDirs |
True | Y Y Y
False | N N N
}
if not IsDotOrDotDot(cFileName) and
((soIncludeSystemHiddenDirs in Options) or not IsSystemAndHidden(FFindData)) then
{ Use case to prevent unnecessary calls to DoCheckDir }
case DirOption of
doExcludeSubDirs, doIncludeSubDirs:
begin
if Search and (soSearchDirs in Options) and DoCheckDir then
DoFindDir(ADirectoryName);
if DirOption = doIncludeSubDirs then
Dirs.AddObject(cFileName, TObject(True))
end;
doExcludeInvalidDirs, doExcludeCompleteInvalidDirs:
begin
DirOK := DoCheckDir;
if Search and (soSearchDirs in Options) and DirOK then
DoFindDir(ADirectoryName);
if (DirOption = doExcludeInvalidDirs) or DirOK then
Dirs.AddObject(cFileName, TObject(DirOK));
end;
end;
end
else
if Search and (soSearchFiles in Options) and DoCheckFile then
DoFindFile(ADirectoryName);
if not FindNextFile(Handle, FFindData) then
begin
Finished := True;
Result := GetLastError = ERROR_NO_MORE_FILES;
end;
end;
finally
Result := FindClose(Handle) and Result;
end;
end;
This is the function given in the previous question but I was never able to get it to work.
function IsJunction(const FileName: string): Boolean;
const
IO_REPARSE_TAG_MOUNT_POINT = $0A0000003;
var
FindHandle: THandle;
FindData: TWin32FindData;
begin
Result := False;
FindHandle := FindFirstFile(PChar(FileName), FindData);
if FindHandle <> INVALID_HANDLE_VALUE then begin
Result := ((FindData.dwFileAttributes and FILE_ATTRIBUTE_REPARSE_POINT)
= FILE_ATTRIBUTE_REPARSE_POINT) and
((FindData.dwReserved0 and IO_REPARSE_TAG_MOUNT_POINT)
= IO_REPARSE_TAG_MOUNT_POINT);
winapi.windows.FindClose(FindHandle);
end else
RaiseLastOSError;
end;
The function you are looking at already has a point at which it skips directories:
if not IsDotOrDotDot(cFileName) and
((soIncludeSystemHiddenDirs in Options) or not IsSystemAndHidden(FFindData)) then
So you can simply extend this condition. However, I would not extend it by adding another and
clause. I personally find if
statements like this to be exceedingly opaque. I would introduce an explanatory variable:
var
SkipDirectory: Boolean;
and then assign it like this:
if IsDotOrDotDot(cFileName) then
SkipDirectory := True
else if IsSystemAndHidden(FFindData) and not (soIncludeSystemHiddenDirs in Options) then
SkipDirectory := True
else if IsJunction(FFindData) then
SkipDirectory := True
else
SkipDirectory := False;
if not SkipDirectory then
....
And then you need to re-work your IsJunction
to receive a TWin32FindData
parameter:
function IsJunction(const FindData: TWin32FindData): Boolean;
const
IO_REPARSE_TAG_MOUNT_POINT = $0A0000003;
begin
Result := ((FindData.dwFileAttributes and FILE_ATTRIBUTE_REPARSE_POINT)
= FILE_ATTRIBUTE_REPARSE_POINT) and
(FindData.dwReserved0 = IO_REPARSE_TAG_MOUNT_POINT);
end;
Although I'd probably re-write @Sertac's if statement to break it up a bit more. But perhaps that's just my personal preference.
function FlagIsSet(Flags, Flag: DWORD): Boolean;
begin
Result := (Flags and Flag)<>0;
end;
function IsJunction(const FindData: TWin32FindData): Boolean;
const
IO_REPARSE_TAG_MOUNT_POINT = $0A0000003;
begin
Result := FlagIsSet(FindData.dwFileAttributes, FILE_ATTRIBUTE_REPARSE_POINT)
and (FindData.dwReserved0=IO_REPARSE_TAG_MOUNT_POINT);
end;